CommonUtils/build.gradle at main · RedlanceMinecraft/CommonUtils · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
plugins {
    id "java-platform"
}

allprojects {
    apply plugin: "maven-publish"

    base.archivesName = "${rootProject.archives_base_name}-${project.name}"
    version = rootProject.mod_version
    group = rootProject.maven_group

    repositories {
        maven {
            name = "Redlance"
            url = "https://repo.redlance.org/public"
        }
        mavenCentral()
    }

    tasks.withType(JavaCompile).configureEach {
        options.encoding = "UTF-8"
        options.release.set 25
    }

    publishing.repositories {
        mavenLocal()
    }
}

subprojects {
    apply plugin: "java"
    apply plugin: "java-library"

    dependencies {
        testImplementation(platform("org.junit:junit-bom:6.0.3"))
        testImplementation("org.junit.jupiter:junit-jupiter-api")
        testImplementation("org.junit.jupiter:junit-jupiter-params")
        testRuntimeOnly("org.junit.jupiter:junit-jupiter-engine")
        testRuntimeOnly("org.junit.platform:junit-platform-launcher")

        testImplementation("org.slf4j:slf4j-api:${slf4j_api_version}")
        testImplementation(project(":log4j"))
    }

    test {
        useJUnitPlatform()
        options {
            systemProperties(System.getProperties())
        }
        jvmArgs("--enable-native-access=ALL-UNNAMED")
        testLogging {
            showStandardStreams = true
        }
    }

    java {
        withSourcesJar()
    }

    publishing.publications {
        mavenJava(MavenPublication) {
            artifactId = project.name
            from components.java
        }
    }
}

publishing.publications {
    register('mavenJava', MavenPublication) {
        from(components['javaPlatform'])
    }
}

tasks.withType(GenerateModuleMetadata).configureEach {
    enabled = true
}

dependencies {
    constraints {
        for (proj in rootProject.subprojects) {
            api(project(proj.path))
        }
    }
}