LightAntiCheat/build.gradle at main · ModernBetaNetwork/LightAntiCheat · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
plugins {
    id 'com.github.johnrengelman.shadow' version '8.1.1'
    id 'java'
    id 'maven-publish'
}

group = 'me.vekster'
version = '1.2.7'

repositories {
    mavenCentral()
    // Config Updater
    maven { url 'https://oss.sonatype.org/content/groups/public/' }
    // Floodgate
    maven { url 'https://repo.opencollab.dev/main/' }
    // FoliaLib
    maven {
        name = "tcoded-releases"
        url = "https://repo.tcoded.com/releases"
    }
}

dependencies {
    // JetBrains Annotations
    implementation 'org.jetbrains:annotations:26.0.1'
    // Lombok
    compileOnly 'org.projectlombok:lombok:1.18.38'
    annotationProcessor 'org.projectlombok:lombok:1.18.38'
    // Spigot API
    compileOnly files('comp/spigot-1.8.8-R0.1-SNAPSHOT-latest.jar')
    // Netty
    compileOnly 'io.netty:netty-all:4.2.3.Final'
    // LightInjector
    implementation files('impl/LightInjector-1.0.2-forked.jar')
    // FoliaLib
    implementation 'com.tcoded:FoliaLib:0.5.1'
    // Floodgate
    compileOnly 'org.geysermc.floodgate:api:2.2.5-SNAPSHOT'
    // Config Updater
    implementation 'com.tchristofferson:ConfigUpdater:2.2'
    // MultiVersion
    implementation fileTree('impl/multiversion')
}

java {
    toolchain {
        languageVersion.set(JavaLanguageVersion.of(8))
    }
}

publishing {
    repositories {
        maven {
            name = "GitHubPackages"
            url = "https://maven.pkg.github.com/tiredvekster/LightAntiCheat"
            credentials {
                username = System.getenv("GITHUB_ACTOR")
                password = System.getenv("GITHUB_TOKEN")
            }
        }
    }


    publications {
        gpr(MavenPublication) {
            from(components.java)
        }
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'
}

processResources {
    def props = [version: version]
    inputs.properties props
    filteringCharset 'UTF-8'
    filesMatching(['plugin.yml']) {
        expand props
    }
}

shadowJar {
    exclude('LICENSE', 'META-INF/**')
    relocate('com.fren_gor', 'org.fren_gor')
    relocate('com.tchristofferson', 'org.tchristofferson')
    relocate('com.tcoded', 'org.tcoded')
    archiveClassifier.set('')
    destinationDirectory.set(file(destinationPath))
}