Expressions-Provider/build.gradle.kts at main · MiniPlaceholders/Expressions-Provider · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
import com.github.jengelman.gradle.plugins.shadow.ShadowPlugin
import org.gradle.internal.extensions.stdlib.capitalized

plugins {
    java
    alias(libs.plugins.shadow)
}

tasks {
    clean {
        delete("jar")
    }
}

subprojects {
    apply<JavaPlugin>()
    apply<ShadowPlugin>()
    java.toolchain.languageVersion.set(JavaLanguageVersion.of(21))

    tasks {
        withType<JavaCompile> {
            options.encoding = Charsets.UTF_8.name()
            options.release.set(21)
        }
        val external = listOf("common", "fabric")
        if (!external.any { project.name.contains(it) }) {
            build {
                dependsOn(shadowJar)
            }
            shadowJar {
                val jarName = project.name
                    .replace("expressions-", "")
                    .capitalized()
                archiveFileName.set("ExpressionsProvider-$jarName-${project.version}.jar")
                archiveClassifier.set("")

                doLast {
                    copy {
                        from(archiveFile)
                        into("${rootProject.projectDir}/jar")
                    }
                }
                duplicatesStrategy = DuplicatesStrategy.EXCLUDE
            }
        }
    }
}