invisibility-plus/build.gradle at main · MModding/invisibility-plus · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
import com.mmodding.gradle.api.EnvironmentTarget

plugins {
	id 'maven-publish'
	alias(libs.plugins.fabric.loom)
	alias(libs.plugins.mmodding.gradle)
}

archivesBaseName = project.archives_base_name
version = "${project.version}+${libs.versions.minecraft.get()}"
group = project.maven_group

repositories {
	maven { url "https://maven.quiltmc.org/repository/release" }
	maven { url 'https://jitpack.io' }
	maven { url 'https://maven.terraformersmc.com/releases/' }
}

// All the dependencies are declared at gradle/libs.version.toml and referenced with "libs.<id>"
// See https://docs.gradle.org/current/userguide/platforms.html for information on how version catalogs work.
dependencies {
	minecraft libs.minecraft

	mappings variantOf(libs.quilt.mappings) { classifier 'intermediary-v2' }

	modImplementation libs.fabric.loader

	// Fabric API
	modImplementation libs.fabric.api

	// MModding Library
	modImplementation libs.mmodding
}

loom {
	mods {
		"invisibility_plus" {
			sourceSet("main")
		}
	}
}

mmodding {
	configureFabricModJson {
		name = "Invisibility Plus"
		namespace = "invisibility_plus"
		group = "com.mmodding"
		description = "Invisibility Plus is a mod that makes the next 4 levels of invisibility potions useful."
		icon = "assets/invisibility_plus/icon.png"
		addAuthor("MModding Team")
		addContributor("FirstMegaGame4")
		withContact {
			it.homepage = "https://mmodding.com"
			it.sources = "https://github.com/MModding/invisibility-plus/issues"
			it.issues = "https://github.com/MModding/invisibility-plus"
		}
		environment = EnvironmentTarget.ANY
		withEntrypoints {
			it.init("com.mmodding.invisibility_plus.InvisibilityPlus")
			it.client("com.mmodding.invisibility_plus.client.InvisibilityPlusClient")
			it.custom("mmodding_bootstrap_init", "com.mmodding.invisibility_plus.bootstrap.InvisibilityPlusBootstrap")
		}
		addMixin("invisibility_plus.mixins.json")
		withDependencies {
			it.javaVersion = ">=" + 17
			it.minecraftVersion = "~" + libs.versions.minecraft.get()
			it.fabricLoaderVersion = ">=" + libs.versions.fabric.loader.get()
			it.fabricApiVersion = ">=" + libs.versions.fabric.api.get()
			it.addDependency("mmodding_lib", ">=" + libs.versions.mmodding.get() + "-")
			// it.mmoddingLibraryVersion = ">=" + libs.versions.mmodding.get()
		}
	}
}

processResources {
	inputs.property "version", version

	filesMatching('fabric.mod.json') {
		expand "version": version
	}
}

tasks.withType(JavaCompile).configureEach {
	it.options.encoding = "UTF-8"
	// Minecraft 1.18 (1.18-pre2) upwards uses Java 17.
	it.options.release = 17
}

java {
	// Still required by IDEs such as Eclipse and Visual Studio Code
	sourceCompatibility = JavaVersion.VERSION_17
	targetCompatibility = JavaVersion.VERSION_17

	// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task if it is present.
	// If you remove this line, sources will not be generated.
	withSourcesJar()

	// If this mod is going to be a library, then it should also generate Javadocs in order to aid with developement.
	// Uncomment this line to generate them.
	// withJavadocJar()
}

// If you plan to use a different file for the license, don't forget to change the file name here!
["jar", "sourcesJar"].each {
	tasks.named(it).configure {
		from("LICENSE.md") {
			rename { "${it}_${archivesBaseName}" }
		}
	}
}

// Configure the maven publication
publishing {
	publications {
		mavenJava(MavenPublication) {
			from components.java
		}
	}

	// See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
	repositories {
		// Add repositories to publish to here.
		// Notice: This block does NOT have the same function as the block in the top level.
		// The repositories here will be used for publishing your artifact, not for
		// retrieving dependencies.
	}
}