DeltaDOM/build.gradle at main · LeapRnD/DeltaDOM · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
import static java.lang.System.getenv
import static org.gradle.api.tasks.testing.logging.TestExceptionFormat.FULL;
import static org.gradle.api.tasks.testing.logging.TestLogEvent.FAILED;

group = "com.leaprnd.deltadom"
version = "1.0.3"

apply plugin: "java-library"

sourceSets {
	test {
		resources {
			srcDir "src/main/javascript"
		}
	}
}

repositories {
	mavenCentral()
}

dependencies {
	implementation group: "com.google.guava", name: "guava", version: "31.1-jre"
	implementation group: "net.sf.trove4j", name: "trove4j", version: "3.0.3"
	testImplementation group: "org.junit.jupiter", name: "junit-jupiter", version: "5.8.2"
	testImplementation group: "net.sf.jtidy", name: "jtidy", version: "r938"
	testImplementation group: "org.mockito", name: "mockito-core", version: "4.4.0"
	testImplementation group: "org.seleniumhq.selenium", name: "selenium-chrome-driver", version: "4.1.3"
	testImplementation group: "org.seleniumhq.selenium", name: "selenium-java", version: "4.1.3"
	testImplementation group: "org.simpleframework", name: "simple-http", version: "6.0.1"
}

test {
	useJUnitPlatform();
	testLogging {
		events FAILED
		exceptionFormat FULL
		showStackTraces true
		showCauses true
	}
}

tasks.withType(Test).configureEach {
	reports.html.required = false
	reports.junitXml.required = false
}

task sourcesJar(type: Jar) {
	archiveClassifier = "sources"
	from sourceSets.main.allSource
}

task javadocJar(type: Jar) {
	archiveClassifier = "javadoc"
	from tasks.javadoc.destinationDir
}

apply plugin: "maven-publish"

publishing {
	publications {
		mavenJava(MavenPublication) {
			from components.java
			artifact sourcesJar
			artifact javadocJar
			pom {
				name = "DeltaDOM"
				description = "A high performance Java library for finding the differences between two HTML documents"
				url = "https://github.com/LeapRnD/DeltaDOM"
				licenses {
					license {
						name = "Apache-2.0"
						url = "https://opensource.org/licenses/Apache-2.0"
					}
				}
				developers {
					developer {
						name = "Ryan Holdren"
						email = "ryan@holdren.ca"
					}
				}
				scm {
					connection = "scm:git:git://github.com/LeapRnD/DeltaDOM.git"
					developerConnection = "scm:git:ssh://github.com/LeapRnD/DeltaDOM.git"
					url = "https://github.com/LeapRnD/DeltaDOM.git"
				}
			}
		}
	}
	repositories {
		maven {
			name = "OSSRH"
			url = "https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/"
			credentials {
				username = getenv("MAVEN_CENTRAL_USERNAME")
				password = getenv("MAVEN_CENTRAL_PASSWORD")
			}
		}
	}
}

apply plugin: "signing"

signing {
	sign publishing.publications
}