Traffic Grid.nlogo

globals
[
  counter                  ;; for ids
  grid-x-inc               ;; the amount of patches in between two roads in the x direction
  grid-y-inc               ;; the amount of patches in between two roads in the y direction
  acceleration             ;; the constant that controls how much a car speeds up or slows down by if
                           ;; it is to accelerate or decelerate
  phase                    ;; keeps track of the phase
  num-cars-stopped         ;; the number of cars that are stopped during a single pass thru the go procedure
  current-light            ;; the currently selected light

  ;; patch agentsets
  intersections ;; agentset containing the patches that are intersections
  roads         ;; agentset containing the patches that are roads
  objective-counter ;; number of objectives done

                ;; Things bellow are for A*

  p-valids      ;; Valid Patches for moving not wall)
  Start         ;; Starting patch
  Final-Cost    ;; The final cost of the path given by A*
]

breed [ cars car ]

cars-own
[
  id
  speed     ;; the speed of the turtle
  up-car?   ;; true if the turtle moves downwards and false if it moves to the right
  wait-time ;; the amount of time since the last time a turtle has moved
  objective ;;
  objectives
  next-cross
  i-go-first
  persistence
  conflicting-cars
  conflicting-car
  path
  next
]

patches-own
[
  intersection?   ;; true if the patch is at the intersection of two roads
  green-light-up? ;; true if the green light is above the intersection.  otherwise, false.
                  ;; false for a non-intersection patches.
  my-row          ;; the row of the intersection counting from the upper left corner of the
                  ;; world.  -1 for non-intersection patches.
  my-column       ;; the column of the intersection counting from the upper left corner of the
                  ;; world.  -1 for non-intersection patches.
  my-phase        ;; the phase for the intersection.  -1 for non-intersection patches.
  auto?           ;; whether or not this intersection will switch automatically.
                  ;; false for non-intersection patches.

                  ;; Things bellow are for A*

  father          ;; Previous patch in this partial path
  Cost-path       ;; Stores the cost of the path to the current patch
  visited?        ;; has the path been visited previously? That is,
                  ;; at least one path has been calculated going through this patch
  active?         ;; is the patch active? That is, we have reached it, but
                  ;; we must consider it because its children have not been explored
]


;;;;;;;;;;;;;;;;;;;;;;
;; Setup Procedures ;;
;;;;;;;;;;;;;;;;;;;;;;

;; Initialize the display by giving the global and patch variables initial values.
;; Create num-cars of turtles if there are enough road patches for one turtle to
;; be created per road patch. Set up the plots.
to setup
  clear-all
  setup-globals

  ;; First we ask the patches to draw themselves and set up a few variables
  setup-patches
  make-current one-of intersections
  label-current

  set-default-shape turtles "car"

  if (num-cars > count roads)
  [
    user-message (word "There are too many cars for the amount of "
                       "road.  Either increase the amount of roads "
                       "by increasing the GRID-SIZE-X or "
                       "GRID-SIZE-Y sliders, or decrease the "
                       "number of cars by lowering the NUMBER slider.\n"
                       "The setup has stopped.")
    stop
  ]

  ;; Now create the turtles and have each created turtle call the functions setup-cars and set-car-color
  create-cars num-cars
  [
    setup-cars
    set-initial-car-color
    record-data
    setObjective
    setPath
  ]

  ;; give the turtles an initial speed
  ask cars [ set-car-speed
    if not (intersection?)
    [set next-cross get-next-crossing
      ;ask next-cross [set pcolor black]
    ]
  ]
  ask cars [send-message "update" self]
  ask cars [set-conflicting-car]
  ask cars[set-passing-first-variable]

  reset-ticks
end

;; Initialize the global variables to appropriate values
to setup-globals
  set counter 0
  set objective-counter 0
  set current-light nobody ;; just for now, since there are no lights yet
  set phase 0
  set num-cars-stopped 0
  set grid-x-inc world-width / grid-size-x
  set grid-y-inc world-height / grid-size-y
  ;; don't make acceleration 0.1 since we could get a rounding error and end up on a patch boundary
  set acceleration 0.099
end

;; Make the patches have appropriate colors, set up the roads and intersections agentsets,
;; and initialize the traffic lights to one setting
to setup-patches
  ;; initialize the patch-owned variables and color the patches to a base-color
  ask patches
  [
    set intersection? false
    set auto? false
    set green-light-up? true
    set my-row -1
    set my-column -1
    set my-phase -1
    set pcolor brown + 3
    set father nobody
    set Cost-path 0
    set visited? false
    set active? false
  ]

  ;; initialize the global variables that hold patch agentsets
  set roads patches with
    [(floor((pxcor + max-pxcor - floor(grid-x-inc - 1)) mod grid-x-inc) = 0) or
    (floor((pycor + max-pycor) mod grid-y-inc) = 0)]
  set intersections roads with
    [(floor((pxcor + max-pxcor - floor(grid-x-inc - 1)) mod grid-x-inc) = 0) and
    (floor((pycor + max-pycor) mod grid-y-inc) = 0)]

  ask roads [ set pcolor white ]
  setup-intersections
end

;; Give the intersections appropriate values for the intersection?, my-row, and my-column
;; patch variables.  Make all the traffic lights start off so that the lights are red
;; horizontally and green vertically.
to setup-intersections
  ask intersections
  [
    set intersection? true
    set green-light-up? true
    set my-phase 0
    set auto? true
    set my-row floor((pycor + max-pycor) / grid-y-inc)
    set my-column floor((pxcor + max-pxcor) / grid-x-inc)
    set-signal-colors
  ]
end

;; Initialize the turtle variables to appropriate values and place the turtle on an empty road patch.
to setup-cars  ;; turtle procedure
  set id counter
  set counter (counter + 1)
  set conflicting-cars 0
  set persistence 0
  set speed 0
  set wait-time 0
  set next 0
  put-on-empty-road
  ifelse intersection?
  [
    ifelse random 2 = 0
    [ set up-car? true ]
    [ set up-car? false ]
  ]
  [
    ; if the turtle is on a vertical road (rather than a horizontal one)
    ifelse (floor((pxcor + max-pxcor - floor(grid-x-inc - 1)) mod grid-x-inc) = 0)
    [ set up-car? true ]
    [ set up-car? false ]
  ]
  ifelse up-car?
  [ set heading 180 ]
  [ set heading 90 ]

end

;; Find a road patch without any turtles on it and place the turtle there.
to put-on-empty-road  ;; turtle procedure
  move-to one-of roads with [(not any? turtles-on self) and (intersection? = false)]
end


;;;;;;;;;;;;;;;;;;;;;;;;
;; Runtime Procedures ;;
;;;;;;;;;;;;;;;;;;;;;;;;

;; Run the simulation
to go

  update-current

  ;; have the intersections change their color
  set-signals
  set num-cars-stopped 0

  ;; set the turtles speed for this time thru the procedure, move them forward their speed,
  ;; record data for plotting, and set the color of the turtles to an appropriate color
  ;; based on their speed
  ask cars [
    if not (color = yellow)
        [set color blue]
    set-car-speed
    nextPatch
    record-data
    set-car-color
    if test-objective
    [setObjective
      set color yellow
    set objective-counter objective-counter + 1
    show objective-counter
    setPath]

    ;;3 kinds of agents: blind agents plan before go, struggler agents replan when they have a lot of other cars around, while provident agents plan from time to time during its trip
    let struggle (count turtles in-radius 2) > 3 and agent_commitment = "Struggler Agent" ;;in this case the agent must be in a struggle to try to replan
    let time-to-replan ticks mod (perseverance + 1)  = id mod (perseverance + 1) and agent_commitment = "Provident Agent"  ;;in this case the agent replan from time to time

    if struggle
    [ ifelse persistence = 0
      [ if not (color = yellow)
        [set color red]
        setPath
        set persistence Perseverance]
      [set persistence persistence - 1]
    ]
    if time-to-replan
    [if not (color = yellow)
      [set color red]
      setPath]

    if not (intersection?) and not (get-next-crossing = next-cross)
    [;ask next-cross [set pcolor white]
      set next-cross get-next-crossing
      set conflicting-cars 0
      send-message "update" self
      ;ask next-cross [set pcolor black]
    ]
    ;;if next = 0 or [pxcor] of patch-here >= [pxcor] of next or [pycor] of patch-here <= [pycor] of next or ([pxcor] of patch-here = max-pxcor and [pxcor] of next = min-pxcor) or ([pycor] of patch-here = min-pycor and [pycor] of next = max-pycor)
  ]

  ;ask cars[
   ; if [pxcor] of next = [pxcor] of objective and [pycor] of next = [pycor] of objective and length path = 0
   ; [setPath
   ;   set next 0]
  ;]

  ;;to tests number of initial conflicting cars
  ;show "Info:"
  ;ask cars [
  ;if conflicting-cars != 0
  ;  [show count conflicting-cars]]

  ask cars [set-conflicting-car]

  ask cars [if not (intersection?)
    [set-passing-first-variable]]

  ask cars [adjust-velocity]
  ;; update the phase and the global clock
  next-phase
  tick
end

to choose-current
  if mouse-down?
  [
    let x-mouse mouse-xcor
    let y-mouse mouse-ycor
    if [intersection?] of patch x-mouse y-mouse
    [
      update-current
      unlabel-current
      make-current patch x-mouse y-mouse
      label-current
      stop
    ]
  ]
end

;; Set up the current light and the interface to change it.
to make-current [light]
  set current-light light
  set current-phase [my-phase] of current-light
  set current-auto? [auto?] of current-light
end

;; update the variables for the current light
to update-current
  ask current-light [
    set my-phase current-phase
    set auto? current-auto?
  ]
end

;; label the current light
to label-current
  ask current-light
  [
    ask patch-at -1 1
    [
      set plabel-color black
      set plabel "current"
    ]
  ]
end

;; unlabel the current light (because we've chosen a new one)
to unlabel-current
  ask current-light
  [
    ask patch-at -1 1
    [
      set plabel ""
    ]
  ]
end

;; have the traffic lights change color if phase equals each intersections' my-phase
to set-signals
  ask intersections with [auto? and phase = floor ((my-phase * ticks-per-cycle) / 100)]
  [
    set green-light-up? (not green-light-up?)
    set-signal-colors
  ]
end

;; This procedure checks the variable green-light-up? at each intersection and sets the
;; traffic lights to have the green light up or the green light to the left.
to set-signal-colors  ;; intersection (patch) procedure
  ifelse power?
  [
    ifelse green-light-up?
    [
      ask patch-at -1 0 [ set pcolor red ]
      ask patch-at 0 1 [ set pcolor green ]
    ]
    [
      ask patch-at -1 0 [ set pcolor green ]
      ask patch-at 0 1 [ set pcolor red ]
    ]
  ]
  [
    ask patch-at -1 0 [ set pcolor white ]
    ask patch-at 0 1 [ set pcolor white ]
  ]
end

;; set the turtles' speed based on whether they are at a red traffic light or the speed of the
;; turtle (if any) on the patch in front of them
to set-car-speed  ;; turtle procedure
  ifelse pcolor = red
  [ set speed 0 ]
  [
    ifelse up-car?
    [ set-speed 0 -1 ]
    [ set-speed 1 0 ]
  ]
end


;changes the turtle direction
to change-direction
  if intersection?
  [
    set up-car? (not up-car?)
    ifelse up-car?
    [ move-to patch-here
      set heading 180
    ]
    [ move-to patch-here
      set heading 90 ]
  ]

end

to nextPatch
  ifelse not empty? path
  [set next item 0 path
    if intersection?
    [
      ifelse heading = 90
      [if pxcor = [pxcor] of next
        [change-direction]]
      [if pycor = [pycor] of next
        [change-direction]]
    ]
    ifelse 18 = pxcor
        [ifelse -18 = pycor
          [if pxcor > [pxcor] of next or pycor < [pycor] of next [fd speed]]
          [if pxcor > [pxcor] of next or pycor > [pycor] of next [fd speed]]]
        [ifelse -18 = pycor
          [if pxcor < [pxcor] of next or pycor < [pycor] of next [fd speed]]
          [if pxcor < [pxcor] of next or pycor > [pycor] of next [fd speed]]]
    set path but-first path]
  [setPath]
end


;; set the speed variable of the car to an appropriate value (not exceeding the
;; speed limit) based on whether there are cars on the patch in front of the car
to set-speed [ delta-x delta-y ]  ;; turtle procedure
  ;; get the turtles on the patch in front of the turtle
  let turtles-ahead turtles-at delta-x delta-y
  let turtles-more-ahead turtles-at delta-x delta-y

  ifelse up-car?
  [set turtles-more-ahead (turtle-set turtles-at delta-x (delta-y - 1) turtles-at delta-x (delta-y - 2))]
  [set turtles-more-ahead (turtle-set turtles-at (delta-x + 1) delta-y turtles-at (delta-x + 2) delta-y)]


  ;; if there are turtles in front of the turtle, slow down
  ;; otherwise, speed up
  ifelse any? turtles-ahead
  [
    ifelse any? (turtles-ahead with [ up-car? != [up-car?] of myself ])
    [
      set speed 0
    ]
    [
      set speed [speed] of one-of turtles-ahead
      slow-down
    ]
  ]
  [
    ifelse any? turtles-more-ahead with [ [speed] of myself < speed]
    [set speed [speed] of one-of turtles-more-ahead
      slow-down]
    [speed-up] ]
end

;; decrease the speed of the turtle
to slow-down  ;; turtle procedure
  set speed speed / 2
  if speed <= 0  ;;if speed < 0
  [ set speed 0 ]
end

;; increase the speed of the turtle
to speed-up  ;; turtle procedure
  ifelse speed > speed-limit
  [ set speed speed-limit ]
  [ set speed speed + acceleration ]
end

;; set the color of the turtle to a different color based on how fast the turtle is moving
to set-initial-car-color  ;; turtle procedure
  ifelse speed < (speed-limit / 2)
    [ set color blue ]
    [ set color cyan - 2 ]
end

;; set the color of the turtle to a different color based on how fast the turtle is moving
to set-car-color  ;; turtle procedure
  if  (not (color = yellow) and not (color = red))
  [ifelse speed < (speed-limit / 2)
    [ set color blue ]
    [ set color cyan - 2 ]
  ]
end

;; keep track of the number of stopped turtles and the amount of time a turtle has been stopped
;; if its speed is 0
to record-data  ;; turtle procedure
  ifelse speed = 0
  [
    set num-cars-stopped num-cars-stopped + 1
    set wait-time wait-time + 1
  ]
  [ set wait-time 0 ]
end

to change-current
  ask current-light
  [
    set green-light-up? (not green-light-up?)
    set-signal-colors
  ]
end

;; cycles phase to the next appropriate value
to next-phase
  ;; The phase cycles from 0 to ticks-per-cycle, then starts over.
  set phase phase + 1
  if phase mod ticks-per-cycle = 0
    [ set phase 0 ]
end

to setObjective
  set objective one-of roads
  while [pxcor = [pxcor] of objective and pycor = [pycor] of objective]
  [ set objective one-of roads ]
end

to setPath
  set path A* patch-here objective roads
end

to-report test-objective
  ifelse pxcor = [pxcor] of objective and pycor = [pycor] of objective
  [report true]
  [report false]
end

;Things below are for negotiation


to-report get-next-crossing
  let c-x-cord  pxcor
  let c-y-cord  pycor
  ifelse up-car?
  [let int-temp intersections with [pxcor = c-x-cord and pycor < c-y-cord]
    ifelse count int-temp = 0
    [report intersections with [pxcor = c-x-cord] with-max [pycor]]
    [report int-temp with-max [pycor]]
  ]
  [let int-temp intersections with [pycor = c-y-cord and pxcor > c-x-cord]
    ifelse count int-temp = 0
    [report intersections with [pycor = c-y-cord] with-min [pxcor]]
    [report int-temp with-min [pxcor]]
  ]

end


;;;  Send a message to all cars
;;;  Sends the next crossing patch, the car turtle with all info
to send-message [msg car-info]
  ask cars [new-message msg car-info false]
end


;;;
;;;  Send a message to a specified car
;;;  Sends the next crossing patch, the car turtle with all info
to send-message-to-car [id-car msg car-info]
  ask cars [
    if id-car = id
    [new-message msg car-info true]]
end

;;;
;;;  Handle a new received message
;;;
to new-message [msg car-info is-return-message]

  if(msg = "update")
  [
    set-conflicting-cars car-info is-return-message


  ]

end

to set-conflicting-cars [car-info is-return-message]
  ;remove past conflict car
    if conflicting-cars != 0
    [if any? conflicting-cars with [ [id] of car-info = [id] of self  ]
      [set conflicting-cars  conflicting-cars with [ [id] of car-info != [id] of self]]]

    if is-conflicting-car car-info
    [ifelse conflicting-cars != 0
      [if not (any? conflicting-cars with [ [pxcor] of self = [pxcor] of car-info and [pycor] of self = [pycor] of car-info ])
        [set conflicting-cars (turtle-set conflicting-cars car-info)
        if not is-return-message
        [send-message-to-car [id] of car-info "update" self]]]
      [set conflicting-cars (turtle-set car-info)
        if not is-return-message
        [send-message-to-car [id] of car-info "update" self]
      ]
    ]
end

to set-conflicting-car
  let my-number 1
  let iterate-cars conflicting-cars
  let temp-car 0

  ifelse conflicting-cars != 0
  [ask conflicting-cars
  [

      if up-car? and [up-car?] of myself
        [if pycor < [pycor] of myself
          [set my-number my-number + 1]]
      if not up-car? and not [up-car?] of myself
        [if pxcor > [pxcor] of myself
          [set my-number my-number + 1]]


  ]
  ask conflicting-cars
  [
    if not up-car? and [up-car?] of myself
      [set iterate-cars iterate-cars with [ not [up-car?] of self]
        while [my-number > 0 and count (iterate-cars with-max [pxcor]) != 0]
          [set temp-car one-of (iterate-cars with-max [pxcor] )
          set iterate-cars  iterate-cars with [ [id] of temp-car != [id] of self]
          set my-number my-number - 1]]
    if up-car? and not [up-car?] of myself
      [set iterate-cars iterate-cars with [  [up-car?] of self]
        while [my-number > 0 and count (iterate-cars with-min [pycor]) != 0]
          [set temp-car one-of (iterate-cars with-min [pycor] )
          set iterate-cars  iterate-cars with [ [id] of temp-car != [id] of self]
          set my-number my-number - 1]]

  ]
  ifelse temp-car != 0 and my-number = 0
  [set conflicting-car temp-car]
  [set conflicting-car 0]
  ;show "lol"
  ;show conflicting-car
  ]
  [set conflicting-car 0]

end

to set-passing-first-variable
  let my-dis 0
  let conf-dis 0
  let conf-id id

  if conflicting-car != 0
  [let conf-car one-of cars with [id = conf-id ]
  ifelse up-car?
    [set my-dis one-of [pycor] of next-cross - pycor
      set conf-dis one-of [pxcor] of next-cross - [pxcor] of conf-car]
    [set my-dis one-of [pxcor] of next-cross - pxcor
      set conf-dis one-of [pycor] of next-cross - [pycor] of conf-car]

  if my-dis < 0
  [set my-dis my-dis * -1]

  if conf-dis < 0
  [set conf-dis conf-dis * -1]

  ifelse speed != 0 and [speed] of conflicting-car != 0
  [ifelse (my-dis / speed) < (conf-dis / [speed] of conf-car) or ((my-dis / speed) = (conf-dis / [speed] of conf-car)  and id < [id] of conf-car)
    [set i-go-first true
      ask cars[
        if id = [id] of [conflicting-car] of myself
        [set i-go-first false]
      ]]
    [set i-go-first false
      ask cars[
        if id = [id] of [conflicting-car] of myself
        [set i-go-first true]
      ]]]
  [ifelse my-dis  < conf-dis or (my-dis = conf-dis and id < [id] of conf-car)
    [set i-go-first true
      ask cars[
        if id = [id] of [conflicting-car] of myself
        [set i-go-first false]
      ]]
    [set i-go-first false
      ask cars[
        if id = [id] of [conflicting-car] of myself
        [set i-go-first true]
      ]]]
  ]

  if conflicting-car = 0
  [set i-go-first true]

end

to adjust-velocity
  let my-dis 0
  let conf-dis 0
  let my-dis-front 0
  let conf-id id

  if conflicting-car != 0
  [let conf-car one-of cars with [id = conf-id]
  ifelse up-car?
    [set my-dis one-of [pycor] of next-cross - pycor
      set conf-dis one-of [pxcor] of next-cross - [pxcor] of conf-car
      set my-dis-front one-of [pycor] of next-cross - (pycor - 1)]
    [set my-dis one-of [pxcor] of next-cross - pxcor
      set conf-dis one-of [pycor] of next-cross - [pycor] of conf-car
    set my-dis-front one-of [pxcor] of next-cross - (pxcor + 1)]

  if my-dis < 0
  [set my-dis my-dis * -1]

  if conf-dis < 0
  [set conf-dis conf-dis * -1]

  if speed != 0 and [speed] of conf-car != 0
  [if ((my-dis / speed) = (conf-dis / [speed] of conf-car)  and i-go-first = false) or ( (my-dis-front / speed) = (conf-dis / [speed] of conf-car)  and i-go-first = false)
    [slow-down]]
  ]

end

to-report is-conflicting-car [car-info]
  ifelse id != [id] of car-info and ([pxcor] of next-cross = [pxcor] of ([next-cross] of car-info)) and ([pycor] of next-cross = [pycor] of ([next-cross] of car-info))
  [report true
  ]
  [report false]
end

to-report is-in-front-car [car-info]
  ifelse id != [id] of car-info and ((not up-car? and ([pxcor] of next-cross > [pxcor] of car-info) and (pycor = [pycor] of car-info)) or (up-car? and (pxcor = [pxcor] of car-info) and ([pycor] of next-cross <  [pycor] of car-info)))
  [report true]
  [report false]
end
; Things bellow are for A*

; Patch report to estimate the total expected cost of the path starting from1
; in Start, passing through it, and reaching the #Goal
to-report Total-expected-cost [#Goal]
  report Cost-path + Heuristic #Goal
end

; Patch report to reurtn the heuristic (expected length) from the current patch
; to the #Goal
to-report Heuristic [#Goal]
  let val (distance #Goal)
  if HeuristicOption = "NumberOfNearTurtles+Distance"
  [set val val + ((count turtles in-radius 2))]
  report val
end

; A* algorithm. Inputs:
;   - #Start     : starting point of the search.
;   - #Goal      : the goal to reach.
;   - #valid-map : set of agents (patches) valid to visit.
; Returns:
;   - If there is a path : list of the agents of the path.
;   - Otherwise          : false

to-report A* [#Start #Goal #valid-map]
  ; clear all the information in the agents
  ask #valid-map with [visited?]
  [
    set father nobody
    set Cost-path 0
    set visited? false
    set active? false
  ]
  ; Active the staring point to begin the searching loop
  ask #Start
  [
    set father self
    set visited? true
    set active? true
  ]
  ; exists? indicates if in some instant of the search there are no options to
  ; continue. In this case, there is no path connecting #Start and #Goal
  let exists? true
  ; The searching loop is executed while we don't reach the #Goal and we think
  ; a path exists
  while [not [visited?] of #Goal and exists?]
  [
    ; We only work on the valid pacthes that are active
    let options #valid-map with [active?]
    ; If any
    ifelse any? options
    [
      ; Take one of the active patches with minimal expected cost
      ask min-one-of options [Total-expected-cost #Goal]
      [
        ; Store its real cost (to reach it) to compute the real cost
        ; of its children
        let Cost-path-father Cost-path
        ; and deactivate it, because its children will be computed right now
        set active? false
        ; Compute its valid neighbors
        let #car self
        let valid-neighbors neighbors with [member? self #valid-map]
        ifelse 18 = pxcor
        [ifelse -18 = pycor
          [set valid-neighbors valid-neighbors with [([pxcor] of #car - [pxcor] of self > 0 and [pycor] of #car = [pycor] of self) or ([pycor] of #car - [pycor] of self < 0 and [pxcor] of #car = [pxcor] of self)]]
          [set valid-neighbors valid-neighbors with [([pxcor] of #car - [pxcor] of self > 0 and [pycor] of #car = [pycor] of self) or ([pycor] of #car - [pycor] of self > 0 and [pxcor] of #car = [pxcor] of self)]]]
        [ifelse -18 = pycor
          [set valid-neighbors valid-neighbors with [([pxcor] of #car - [pxcor] of self < 0 and [pycor] of #car = [pycor] of self) or ([pycor] of #car - [pycor] of self < 0 and [pxcor] of #car = [pxcor] of self)]]
          [set valid-neighbors valid-neighbors with [([pxcor] of #car - [pxcor] of self < 0 and [pycor] of #car = [pycor] of self) or ([pycor] of #car - [pycor] of self > 0 and [pxcor] of #car = [pxcor] of self)]]]
        ask valid-neighbors
        [
          ; There are 2 types of valid neighbors:
          ;   - Those that have never been visited (therefore, the
          ;       path we are building is the best for them right now)
          ;   - Those that have been visited previously (therefore we
          ;       must check if the path we are building is better or not,
          ;       by comparing its expected length with the one stored in
          ;       the patch)
          ; One trick to work with both type uniformly is to give for the
          ; first case an upper bound big enough to be sure that the new path
          ; will always be smaller.
          let t ifelse-value visited? [ Total-expected-cost #Goal] [2 ^ 20]
          ; If this temporal cost is worse than the new one, we substitute the
          ; information in the patch to store the new one (with the neighbors
          ; of the first case, it will be always the case)
          if t > (Cost-path-father + distance myself + Heuristic #Goal)
          [
            ; The current patch becomes the father of its neighbor in the new path
            set father myself
            set visited? true
            set active? true
            ; and store the real cost in the neighbor from the real cost of its father
            set Cost-path Cost-path-father + distance father
            set Final-Cost precision Cost-path 3
          ]
        ]
      ]
    ]
    ; If there are no more options, there is no path between #Start and #Goal
    [
      set exists? false
    ]
  ]
  ; After the searching loop, if there exists a path
  ifelse exists?
  [
    ; We extract the list of patches in the path, form #Start to #Goal
    ; by jumping back from #Goal to #Start by using the fathers of every patch
    let current #Goal
    set Final-Cost (precision [Cost-path] of #Goal 3)
    let rep (list current)
    While [current != #Start]
    [
      set current [father] of current
      set rep fput current rep
    ]
    report rep
  ]
  [
    ; Otherwise, there is no path, and we return False
    report false
  ]
end

; Copyright 2003 Uri Wilensky.
; See Info tab for full copyright and license.
@#$#@#$#@
GRAPHICS-WINDOW
327
10
668
352
-1
-1
9.0
1
12
1
1
1
0
1
1
1
-18
18
-18
18
1
1
1
ticks
30.0

PLOT
453
377
671
541
Average Wait Time of Cars
Time
Average Wait
0.0
100.0
0.0
5.0
true
false
"" ""
PENS
"default" 1.0 0 -16777216 true "" "plot mean [wait-time] of turtles"

PLOT
228
377
444
542
Average Speed of Cars
Time
Average Speed
0.0
100.0
0.0
1.0
true
false
"set-plot-y-range 0 speed-limit" ""
PENS
"default" 1.0 0 -16777216 true "" "plot mean [speed] of turtles"

SLIDER
108
35
205
68
grid-size-y
grid-size-y
1
9
9.0
1
1
NIL
HORIZONTAL

SLIDER
12
35
106
68
grid-size-x
grid-size-x
1
9
9.0
1
1
NIL
HORIZONTAL

SWITCH
12
107
107
140
power?
power?
1
1
-1000

SLIDER
12
71
293
104
num-cars
num-cars
1
400
150.0
1
1
NIL
HORIZONTAL

PLOT
5
376
219
540
Stopped Cars
Time
Stopped Cars
0.0
100.0
0.0
100.0
true
false
"set-plot-y-range 0 num-cars" ""
PENS
"default" 1.0 0 -16777216 true "" "plot num-cars-stopped"

BUTTON
221
184
285
217
Go
go
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
0

BUTTON
208
35
292
68
Setup
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SLIDER
11
177
165
210
speed-limit
speed-limit
0.1
1
1.0
0.1
1
NIL
HORIZONTAL

MONITOR
205
132
310
177
Current Phase
phase
3
1
11

SLIDER
11
143
165
176
ticks-per-cycle
ticks-per-cycle
1
100
35.0
1
1
NIL
HORIZONTAL

SLIDER
146
256
302
289
current-phase
current-phase
0
99
0.0
1
1
%
HORIZONTAL

BUTTON
9
292
143
325
Change light
change-current
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
0

SWITCH
9
256
144
289
current-auto?
current-auto?
0
1
-1000

BUTTON
145
292
300
325
Select intersection
choose-current
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
0

MONITOR
679
12
790
57
NIL
objective-counter
17
1
11

PLOT
677
378
908
542
Objectives per tick per Car
Time
Objectives
0.0
10.0
0.2
0.7
true
false
"" ""
PENS
"default" 1.0 0 -16777216 true "" "plot objective-counter * 100 / (ticks * count turtles + 0.001)"

MONITOR
793
10
1009
55
Objectives per tick per Car
objective-counter * 100 / (ticks * count turtles)
17
1
11

CHOOSER
680
60
906
105
HeuristicOption
HeuristicOption
"OnlyDistance" "NumberOfNearTurtles+Distance"
1

SLIDER
680
155
907
188
Perseverance
Perseverance
1
10
10.0
1
1
NIL
HORIZONTAL

CHOOSER
680
108
906
153
agent_commitment
agent_commitment
"Blind Agent" "Struggler Agent" "Provident Agent"
2

@#$#@#$#@
## WHAT IS IT?

This is a model of traffic moving in a city grid. It allows you to control traffic lights and global variables, such as the speed limit and the number of cars, and explore traffic dynamics.

Try to develop strategies to improve traffic and to understand the different ways to measure the quality of traffic.

## HOW IT WORKS

Each time step, the cars attempt to move forward at their current speed.  If their current speed is less than the speed limit and there is no car directly in front of them, they accelerate.  If there is a slower car in front of them, they match the speed of the slower car and deccelerate.  If there is a red light or a stopped car in front of them, they stop.

There are two different ways the lights can change.  First, the user can change any light at any time by making the light current, and then clicking CHANGE LIGHT.  Second, lights can change automatically, once per cycle.  Initially, all lights will automatically change at the beginning of each cycle.

## HOW TO USE IT

Change the traffic grid (using the sliders GRID-SIZE-X and GRID-SIZE-Y) to make the desired number of lights.  Change any other of the settings that you would like to change.  Press the SETUP button.

At this time, you may configure the lights however you like, with any combination of auto/manual and any phase. Changes to the state of the current light are made using the CURRENT-AUTO?, CURRENT-PHASE and CHANGE LIGHT controls.  You may select the current intersection using the SELECT INTERSECTION control.  See below for details.

Start the simulation by pressing the GO button.  You may continue to make changes to the lights while the simulation is running.

### Buttons

SETUP - generates a new traffic grid based on the current GRID-SIZE-X and GRID-SIZE-Y and NUM-CARS number of cars.  This also clears all the plots. All lights are set to auto, and all phases are set to 0.
GO - runs the simulation indefinitely
CHANGE LIGHT - changes the direction traffic may flow through the current light. A light can be changed manually even if it is operating in auto mode.
SELECT INTERSECTION - allows you to select a new "current" light. When this button is depressed, click in the intersection which you would like to make current. When you've selected an intersection, the "current" label will move to the new intersection and this button will automatically pop up.

### Sliders

SPEED-LIMIT - sets the maximum speed for the cars
NUM-CARS - the number of cars in the simulation (you must press the SETUP button to see the change)
TICKS-PER-CYCLE - sets the number of ticks that will elapse for each cycle.  This has no effect on manual lights.  This allows you to increase or decrease the granularity with which lights can automatically change.
GRID-SIZE-X - sets the number of vertical roads there are (you must press the SETUP button to see the change)
GRID-SIZE-Y - sets the number of horizontal roads there are (you must press the SETUP button to see the change)
CURRENT-PHASE - controls when the current light changes, if it is in auto mode. The slider value represents the percentage of the way through each cycle at which the light should change. So, if the TICKS-PER-CYCLE is 20 and CURRENT-PHASE is 75%, the current light will switch at tick 15 of each cycle.

### Switches

POWER? - toggles the presence of traffic lights
CURRENT-AUTO? - toggles the current light between automatic mode, where it changes once per cycle (according to CURRENT-PHASE), and manual, in which you directly control it with CHANGE LIGHT.

### Plots

STOPPED CARS - displays the number of stopped cars over time
AVERAGE SPEED OF CARS - displays the average speed of cars over time
AVERAGE WAIT TIME OF CARS - displays the average time cars are stopped over time

## THINGS TO NOTICE

When cars have stopped at a traffic light, and then they start moving again, the traffic jam will move backwards even though the cars are moving forwards.  Why is this?

When POWER? is turned off and there are quite a few cars on the roads, "gridlock" usually occurs after a while.  In fact, gridlock can be so severe that traffic stops completely.  Why is it that no car can move forward and break the gridlock?  Could this happen in the real world?

Gridlock can occur when the power is turned on, as well.  What kinds of situations can lead to gridlock?

## THINGS TO TRY

Try changing the speed limit for the cars.  How does this affect the overall efficiency of the traffic flow?  Are fewer cars stopping for a shorter amount of time?  Is the average speed of the cars higher or lower than before?

Try changing the number of cars on the roads.  Does this affect the efficiency of the traffic flow?

How about changing the speed of the simulation?  Does this affect the efficiency of the traffic flow?

Try running this simulation with all lights automatic.  Is it harder to make the traffic move well using this scheme than controlling one light manually?  Why?

Try running this simulation with all lights automatic.  Try to find a way of setting the phases of the traffic lights so that the average speed of the cars is the highest.  Now try to minimize the number of stopped cars.  Now try to decrease the average wait time of the cars.  Is there any correlation between these different metrics?

## EXTENDING THE MODEL

Currently, the maximum speed limit (found in the SPEED-LIMIT slider) for the cars is 1.0.  This is due to the fact that the cars must look ahead the speed that they are traveling to see if there are cars ahead of them.  If there aren't, they speed up.  If there are, they slow down.  Looking ahead for a value greater than 1 is a little bit tricky.  Try implementing the correct behavior for speeds greater than 1.

When a car reaches the edge of the world, it reappears on the other side.  What if it disappeared, and if new cars entered the city at random locations and intervals?

## NETLOGO FEATURES

This model uses two forever buttons which may be active simultaneously, to allow the user to select a new current intersection while the model is running.

It also uses a chooser to allow the user to choose between several different possible plots, or to display all of them at once.

## RELATED MODELS

- "Traffic Basic": a simple model of the movement of cars on a highway.

- "Traffic Basic Utility": a version of "Traffic Basic" including a utility function for the cars.

- "Traffic Basic Adaptive": a version of "Traffic Basic" where cars adapt their acceleration to try and maintain a smooth flow of traffic.

- "Traffic Basic Adaptive Individuals": a version of "Traffic Basic Adaptive" where each car adapts individually, instead of all cars adapting in unison.

- "Traffic 2 Lanes": a more sophisticated two-lane version of the "Traffic Basic" model.

- "Traffic Intersection": a model of cars traveling through a single intersection.

- "Traffic Grid Goal": a version of "Traffic Grid" where the cars have goals, namely to drive to and from work.

- "Gridlock HubNet": a version of "Traffic Grid" where students control traffic lights in real-time.

- "Gridlock Alternate HubNet": a version of "Gridlock HubNet" where students can enter NetLogo code to plot custom metrics.

## HOW TO CITE

If you mention this model or the NetLogo software in a publication, we ask that you include the citations below.

For the model itself:

* Wilensky, U. (2003).  NetLogo Traffic Grid model.  http://ccl.northwestern.edu/netlogo/models/TrafficGrid.  Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

Please cite the NetLogo software as:

* Wilensky, U. (1999). NetLogo. http://ccl.northwestern.edu/netlogo/. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

## COPYRIGHT AND LICENSE

Copyright 2003 Uri Wilensky.

![CC BY-NC-SA 3.0](http://ccl.northwestern.edu/images/creativecommons/byncsa.png)

This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 License.  To view a copy of this license, visit https://creativecommons.org/licenses/by-nc-sa/3.0/ or send a letter to Creative Commons, 559 Nathan Abbott Way, Stanford, California 94305, USA.

Commercial licenses are also available. To inquire about commercial licenses, please contact Uri Wilensky at uri@northwestern.edu.

This model was created as part of the projects: PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN CLASSROOMS and/or INTEGRATED SIMULATION AND MODELING ENVIRONMENT. The project gratefully acknowledges the support of the National Science Foundation (REPP & ROLE programs) -- grant numbers REC #9814682 and REC-0126227.

<!-- 2003 -->
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
true
0
Polygon -7500403 true true 180 15 164 21 144 39 135 60 132 74 106 87 84 97 63 115 50 141 50 165 60 225 150 285 165 285 225 285 225 15 180 15
Circle -16777216 true false 180 30 90
Circle -16777216 true false 180 180 90
Polygon -16777216 true false 80 138 78 168 135 166 135 91 105 106 96 111 89 120
Circle -7500403 true true 195 195 58
Circle -7500403 true true 195 47 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270
@#$#@#$#@
NetLogo 6.0.1
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180
@#$#@#$#@
0
@#$#@#$#@