JsMacros/settings.gradle.kts at main · JsMacrosCE/JsMacros · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
pluginManagement {
    repositories {
        gradlePluginPortal()
        mavenCentral()
        maven("https://maven.kikugie.dev/snapshots") { name = "KikuGie Snapshots" }

        exclusiveContent {
            forRepository {
                maven {
                    name = "Fabric"
                    url = uri("https://maven.fabricmc.net")
                }
            }
            filter {
                includeGroupAndSubgroups("net.fabricmc")
                includeGroupAndSubgroups("fabric-loom")
            }
        }

        exclusiveContent {
            forRepository {
                maven {
                    name = "Sponge"
                    url = uri("https://repo.spongepowered.org/repository/maven-public")
                }
            }
            filter {
                includeGroupAndSubgroups("org.spongepowered")
            }
        }

        exclusiveContent {
            forRepository {
                maven {
                    name = "NeoForge"
                    url = uri("https://maven.neoforged.net/releases")
                }
            }
            filter {
                includeGroupAndSubgroups("net.neoforged")
            }
        }
    }

    plugins {
        // see https://fabricmc.net/develop/ for new versions
        id("fabric-loom") version "1.13-SNAPSHOT" apply false
        // see https://projects.neoforged.net/neoforged/moddevgradle for new versions
        id("net.neoforged.moddev") version "2.0.139" apply false
    }
}

plugins {
	id("dev.kikugie.stonecutter") version "0.8.3"
    id("org.gradle.toolchains.foojay-resolver-convention") version "0.8.0"
}

// This should match the folder name of the project, or else IDEA may complain (see https://youtrack.jetbrains.com/issue/IDEA-317606)
rootProject.name = "JsMacrosCE"

include("common")
include("fabric")
include("neoforge")
include("extension")
include("extension:graal")
include("extension:graal:js")
include("extension:graal:python")

stonecutter {
    kotlinController = true
    centralScript = "build.gradle.kts"

    create(rootProject) {
        versions("1.21.5", "1.21.8", "1.21.10", "1.21.11")

        branch("common") {
            versions("1.21.5", "1.21.8", "1.21.10", "1.21.11")
        }
        branch("fabric") {
            versions("1.21.5", "1.21.8", "1.21.10", "1.21.11")
        }
        branch("neoforge") {
            versions("1.21.5", "1.21.8", "1.21.10", "1.21.11")
        }
    }
}