gitout/build.gradle at trunk · JakeWharton/gitout · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
import org.jetbrains.kotlin.gradle.dsl.JvmTarget
import org.jetbrains.kotlin.gradle.tasks.KotlinJvmCompile

buildscript {
	dependencies {
		classpath libs.kotlin.gradlePlugin
		classpath libs.kotlin.serializationPlugin
		classpath libs.poko.gradlePlugin
		classpath libs.buildConfig.gradlePlugin
		classpath libs.apollo.gradlePlugin
	}
	repositories {
		mavenCentral()
		gradlePluginPortal()
	}
}

apply plugin: 'org.jetbrains.kotlin.jvm'
apply plugin: 'org.jetbrains.kotlin.plugin.serialization'
apply plugin: 'dev.drewhamilton.poko'
apply plugin: 'com.github.gmazzo.buildconfig'
apply plugin: 'com.apollographql.apollo'
apply plugin: 'application'

version = '0.4.0-SNAPSHOT'

kotlin {
	explicitApi()
}

dependencies {
	implementation libs.clikt
	implementation libs.cardiologist
	implementation libs.okhttp.core
	implementation libs.okhttp.loggingInterceptor
	implementation libs.ktoml
	implementation libs.kotlinx.serialization.core
	implementation libs.apollo.runtime

	testImplementation libs.junit
	testImplementation libs.assertk
}

apollo {
	service('github') {
		packageName.set('com.jakewharton.gitout')
	}
}

application {
	mainClass = 'com.jakewharton.gitout.Main'
}

buildConfig {
	useKotlinOutput {
		internalVisibility = true
		topLevelConstants = true
	}

	packageName('com.jakewharton.gitout')
	buildConfigField("String", "version", "\"${project.version}\"")
}

tasks.withType(JavaCompile).configureEach { task ->
	task.sourceCompatibility = '1.8'
	task.targetCompatibility = '1.8'
}

tasks.withType(KotlinJvmCompile).configureEach { task ->
	task.compilerOptions {
		jvmTarget = JvmTarget.JVM_1_8
		freeCompilerArgs.add('-Xjdk-release=8')
		freeCompilerArgs.add('-Xjvm-default=all')
		freeCompilerArgs.add('-opt-in=kotlin.time.ExperimentalTime')
	}
}