terraform-github-workspace/repo_files.tf at main · HappyPathway/terraform-github-workspace · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
# Resource to create a GitHub repository file for Terraform apply workflow
resource "github_repository_file" "plan" {
  for_each            = tomap({ for env in var.environments : env.name => env })
  repository          = local.repo.name
  file                = ".github/workflows/terraform-plan-${each.value.name}.yml"
  overwrite_on_create = true
  content = templatefile(
    "${path.module}/workflow-templates/terraform-plan.tftpl",
    {
      repo_name       = local.repo.name,
      repo_org        = var.repo.repo_org,
      branch          = compact([each.value.deployment_branch_policy.branch, local.repo.default_branch])[0],
      runs_on         = each.value.runner_group,
      aws_auth        = var.composite_action_repos.aws_auth,
      gh_auth         = var.composite_action_repos.gh_auth,
      setup_terraform = var.composite_action_repos.setup_terraform,
      terraform_init  = var.composite_action_repos.terraform_init,
      terraform_plan  = var.composite_action_repos.terraform_plan,
      terraform_apply = var.composite_action_repos.terraform_apply,
      checkout        = var.composite_action_repos.checkout,
      environment     = lookup(github_repository_environment.this, each.value.name).environment
      backend_config  = each.value.state_config.set_backend ? "backend-configs/${each.key}.tf" : "backend.tf"
      cache_bucket    = each.value.cache_bucket
      s3_cleanup      = var.composite_action_repos.s3_cleanup
      vars = distinct(concat(
        [for var in var.repo.vars : var.name],
        [for var in each.value.vars : var.name]
      ))
      secrets = distinct(concat(
        [for secret in var.repo.secrets : secret.name],
        [for secret in each.value.secrets : secret.name]
      ))
    }
  )
  branch = local.repo.default_branch
  lifecycle {
    ignore_changes = [
      branch,
    ]
  }
}

# Resource to create a GitHub repository file for Terraform apply workflow
resource "github_repository_file" "apply" {
  for_each            = tomap({ for env in var.environments : env.name => env })
  repository          = local.repo.name
  file                = ".github/workflows/terraform-apply-${each.value.name}.yml"
  overwrite_on_create = true
  content = templatefile(
    "${path.module}/workflow-templates/terraform-apply.tftpl",
    {
      repo_name       = local.repo.name,
      repo_org        = var.repo.repo_org,
      branch          = compact([each.value.deployment_branch_policy.branch, local.repo.default_branch])[0],
      runs_on         = each.value.runner_group,
      aws_auth        = var.composite_action_repos.aws_auth,
      gh_auth         = var.composite_action_repos.gh_auth,
      setup_terraform = var.composite_action_repos.setup_terraform,
      terraform_init  = var.composite_action_repos.terraform_init,
      terraform_plan  = var.composite_action_repos.terraform_plan,
      terraform_apply = var.composite_action_repos.terraform_apply,
      checkout        = var.composite_action_repos.checkout,
      environment     = lookup(github_repository_environment.this, each.value.name).environment
      backend_config  = each.value.state_config.set_backend ? "backend-configs/${each.key}.tf" : "backend.tf"
      cache_bucket    = each.value.cache_bucket
      s3_cleanup      = var.composite_action_repos.s3_cleanup
      vars = distinct(concat(
        [for var in var.repo.vars : var.name],
        [for var in each.value.vars : var.name]
      ))
      secrets = distinct(concat(
        [for secret in var.repo.secrets : secret.name],
        [for secret in each.value.secrets : secret.name]
      ))
    }
  )
  branch = local.repo.default_branch
  lifecycle {
    ignore_changes = [
      branch,
    ]
  }
}
locals {
  # Create a map of environment-specific backend configurations
  environment_specific_backend_configs = {
    for env in var.environments : env.name => merge(
      env.state_config,
      {
        path = "backend-configs/${env.name}.tf",
        key  = "${env.state_config.key_prefix}/${env.name}.tfstate",
      }
    )
    if env.state_config.set_backend
  }

  # Global backend configuration
  global_backend_config = merge(
    var.state_config,
    {
      path = "backend.tf",
      key  = "${var.state_config.key_prefix}/terraform.tfstate",
    }
  )

  # Merge environment-specific and global backend configurations
  backend_configs = merge(
    local.environment_specific_backend_configs,
    var.state_config.set_backend ? { "global" = local.global_backend_config } : {}
  )
}

# Resource to create a GitHub repository file for Terraform init workflow
resource "github_repository_file" "env_backend_tf" {
  for_each            = tomap(local.backend_configs)
  repository          = local.repo.name
  file                = each.value.path
  overwrite_on_create = true
  content = templatefile(
    "${path.module}/workflow-templates/backend.tpl",
    {
      bucket         = each.value.bucket,
      key            = each.value.key,
      region         = each.value.region,
      dynamodb_table = each.value.dynamodb_table
    }
  )
}

resource "github_repository_file" "varfiles" {
  for_each            = tomap({ for environment in var.environments : environment.name => environment })
  repository          = local.repo.name
  file                = "varfiles/${each.value.name}.tfvars"
  overwrite_on_create = true
  content             = "# Add Terraform Variables here"
  lifecycle {
    ignore_changes = [
      branch,
      content
    ]
  }
}

resource "github_repository_file" "backend_tf" {
  count               = var.state_config.set_backend ? 0 : 1
  repository          = local.repo.name
  file                = "backend.tf"
  overwrite_on_create = true
  content             = file("${path.module}/workflow-templates/backend.tf")
  lifecycle {
    ignore_changes = [
      branch,
      content
    ]
  }
}