LuckPerms/build.gradle at master · FreshSMP/LuckPerms · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
plugins {
    alias(libs.plugins.licenser) apply false
    alias(libs.plugins.loom) apply false
}

import org.gradle.api.tasks.testing.logging.TestExceptionFormat
import org.gradle.api.tasks.testing.logging.TestLogEvent

subprojects {
    apply plugin: 'java'
    apply plugin: 'maven-publish'
    apply plugin: 'dev.yumi.gradle.licenser'

    group = 'me.lucko.luckperms'
    version = '5.5-SNAPSHOT'

    tasks.withType(JavaCompile).configureEach {
        options.encoding = 'UTF-8'
        options.release = 11
    }

    tasks.withType(Test).configureEach {
        testLogging {
            events = [TestLogEvent.PASSED, TestLogEvent.FAILED, TestLogEvent.SKIPPED]
            exceptionFormat = TestExceptionFormat.FULL
            showExceptions = true
            showCauses = true
            showStackTraces = true
        }
    }

    jar {
        from '../LICENSE.txt'
    }

    def determinePatchVersion = {
        def tagInfo = providers.exec {
            commandLine 'git', 'describe', '--tags'
        }.standardOutput.asText.get().trim()

        return tagInfo.contains('-') ? tagInfo.split('-')[1] : 0
    }

    project.ext.majorVersion = '5'
    project.ext.minorVersion = '5'
    project.ext.patchVersion = determinePatchVersion()
    project.ext.apiVersion = project.ext.majorVersion + '.' + project.ext.minorVersion
    project.ext.fullVersion = project.ext.apiVersion + '.' + project.ext.patchVersion

    license {
        rule(rootProject.file("HEADER.txt"))
        exclude '*.xml'
    }

    repositories {
        // Fix issue with lwjgl-freetype not being found on macOS / ForgeGradle issue
        //
        // Could not resolve all files for configuration ':_compileJava_1'.
        // Could not find lwjgl-freetype-3.3.3-natives-macos-patch.jar (org.lwjgl:lwjgl-freetype:3.3.3).
        maven {
            url "https://libraries.minecraft.net"
            content {
                includeModule("org.lwjgl", "lwjgl-freetype")
            }
        }
        mavenCentral()
        maven { url 'https://repo.lucko.me/' }
        maven { url 'https://libraries.minecraft.net/' }
    }
}