github-foundations-modules/modules/ruleset/organization_ruleset.tf at d758b84f3c3aff7ef3180c888e0e8d06caf707ed · FociSolutions/github-foundations-modules · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
resource "github_organization_ruleset" "ruleset" {
  count = var.ruleset_type == "organization" ? 1 : 0

  name        = var.name
  target      = var.target
  enforcement = var.enforcement

  dynamic "conditions" {
    for_each = length(concat(var.ref_name_inclusions, var.ref_name_exclusions)) > 0 ? [1] : []
    content {
      ref_name {
        include = var.ref_name_inclusions
        exclude = var.ref_name_exclusions
      }

      repository_name {
        include = var.repository_name_inclusions
        exclude = var.repository_name_exclusions
      }
    }
  }

  rules {
    creation                = var.rules.creation
    update                  = var.rules.update
    deletion                = var.rules.deletion
    non_fast_forward        = var.rules.non_fast_forward
    required_linear_history = var.rules.required_linear_history
    required_signatures     = var.rules.required_signatures

    dynamic "branch_name_pattern" {
      for_each = var.rules.branch_name_pattern != null ? [var.rules.branch_name_pattern] : []

      content {
        operator = branch_name_pattern.value.operator
        pattern  = branch_name_pattern.value.pattern
        name     = branch_name_pattern.value.name
        negate   = coalesce(branch_name_pattern.value.negate, false)
      }
    }

    dynamic "tag_name_pattern" {
      for_each = var.rules.tag_name_pattern != null ? [var.rules.tag_name_pattern] : []

      content {
        operator = tag_name_pattern.value.operator
        pattern  = tag_name_pattern.value.pattern
        name     = tag_name_pattern.value.name
        negate   = coalesce(tag_name_pattern.value.negate, false)
      }
    }

    dynamic "commit_author_email_pattern" {
      for_each = var.rules.commit_author_email_pattern != null ? [var.rules.commit_author_email_pattern] : []

      content {
        operator = commit_author_email_pattern.value.operator
        pattern  = commit_author_email_pattern.value.pattern
        name     = commit_author_email_pattern.value.name
        negate   = coalesce(commit_author_email_pattern.value.negate, false)
      }
    }

    dynamic "commit_message_pattern" {
      for_each = var.rules.commit_message_pattern != null ? [var.rules.commit_message_pattern] : []

      content {
        operator = commit_message_pattern.value.operator
        pattern  = commit_message_pattern.value.pattern
        name     = commit_message_pattern.value.name
        negate   = coalesce(commit_message_pattern.value.negate, false)
      }
    }

    dynamic "committer_email_pattern" {
      for_each = var.rules.committer_email_pattern != null ? [var.rules.committer_email_pattern] : []

      content {
        operator = committer_email_pattern.value.operator
        pattern  = committer_email_pattern.value.pattern
        name     = committer_email_pattern.value.name
        negate   = coalesce(committer_email_pattern.value.negate, false)
      }
    }

    dynamic "pull_request" {
      for_each = var.rules.pull_request != null ? [var.rules.pull_request] : []

      content {
        dismiss_stale_reviews_on_push     = coalesce(pull_request.value.dismiss_stale_reviews_on_push, false)
        require_code_owner_review         = coalesce(pull_request.value.require_code_owner_review, false)
        require_last_push_approval        = coalesce(pull_request.value.require_last_push_approval, false)
        required_approving_review_count   = coalesce(pull_request.value.required_approving_review_count, 0)
        required_review_thread_resolution = coalesce(pull_request.value.required_review_thread_resolution, false)
      }
    }

    dynamic "required_status_checks" {
      for_each = var.rules.required_status_checks != null ? [var.rules.required_status_checks] : []

      content {
        dynamic "required_check" {
          for_each = required_status_checks.value.required_check

          content {
            context        = required_check.value.context
            integration_id = required_check.value.integration_id
          }
        }

        strict_required_status_checks_policy = required_status_checks.value.strict_required_status_check_policy
      }
    }

    dynamic "required_workflows" {
      for_each = var.rules.required_workflows != null ? [var.rules.required_workflows] : []

      content {

        dynamic "required_workflow" {
          for_each = required_workflows.value.required_workflows

          content {
            repository_id = required_workflow.value.repository_id
            path          = required_workflow.value.path
            ref           = coalesce(required_workflow.value.ref, "main")
          }
        }
      }
    }
  }

  dynamic "bypass_actors" {
    for_each = var.bypass_actors != null ? toset(coalesce(var.bypass_actors.repository_roles, [])) : []

    content {
      actor_id    = bypass_actors.value.role_id
      actor_type  = "RepositoryRole"
      bypass_mode = coalesce(bypass_actors.value.always_bypass, false) ? "always" : "pull_request"
    }
  }

  dynamic "bypass_actors" {
    for_each = var.bypass_actors != null ? toset(coalesce(var.bypass_actors.teams, [])) : []

    content {
      actor_id    = bypass_actors.value.team_id
      actor_type  = "Team"
      bypass_mode = coalesce(bypass_actors.value.always_bypass, false) ? "always" : "pull_request"
    }
  }

  dynamic "bypass_actors" {
    for_each = var.bypass_actors != null ? toset(coalesce(var.bypass_actors.integrations, [])) : []

    content {
      actor_id    = bypass_actors.value.installation_id
      actor_type  = "Integration"
      bypass_mode = coalesce(bypass_actors.value.always_bypass, false) ? "always" : "pull_request"
    }
  }

  dynamic "bypass_actors" {
    for_each = var.bypass_actors.organization_admin != null ? [1] : []

    content {
      # Although provider docs suggest the ID can be fixed to 1, it has been recently changed to 0 - https://github.com/integrations/terraform-provider-github/issues/2536
      actor_id    = 0
      actor_type  = "OrganizationAdmin"
      bypass_mode = coalesce(var.bypass_actors.organization_admin.always_bypass, false) ? "always" : "pull_request"
    }
  }
}