0 Start - paper.bat

@echo off
set dontsearch=0
set buildsonlinenumbers=0
:firsttime
chcp 65001 > nul
chcp 1252 > nul
rem config
rem %WINDIR%\media\Alarm*.wav
rem %WINDIR%\media\Ring*.wav
set vers=10
set newversionfound_randomsong=%WINDIR%\media\Alarm*.wav
set version=1.21.4
set dontprompt=1
set latestnewsinfileandanotherscreen=1
set title=Serveur de Nini et Jo
rem end config

set build=0
set versionfile=paper_version.txt
set latestnewsfile=paper_latestnews.bat
set firsttime=0
SET BINDIR=%~dp0
CD /D "%BINDIR%"
Title Flash Server loader V%vers%

rem test
rem echo. test mode:
rem call :checkonlinebuild 1.21.1 0
rem call :pause 5
rem call :checkonlinebuild 1.21.3 0
rem call :descriptions 1.19.2 244 0
rem call :downloadpapermc 1.19.2 191
rem echo fin
rem pause

if not exist %versionfile% (
  echo.
  echo. ***********************************
  echo. ***** Flash Server loader V%vers% ******
  echo. ****** Première utilisation. ******
  echo. ***********************************
  echo.
  type nul >%versionfile%
  echo %version% 0>%versionfile%
  set firsttime=1
  call :pause 4
)

set /p readversion=< %versionfile%
set newversiondetected=0

for /F "tokens=1,2 delims= " %%a in ("%readversion%") do (
  rem set version=%%a
  if %%a neq %version% (
    call :title 1
    echo. Changement de version detecté %%a - %version%
    call :pause 5
    goto dontsetbuild
  )
  set build=%%b
)
:dontsetbuild
if %firsttime% == 0 (
  call :title 1
)
set fichierActuel=paper-%version%-%build%.jar
call :pause 2
set filefound=0
::ici etait local check
call :checklocalversion %build%
::end
if %filefound% == 0 (
  cls
  echo.
  echo. ***********************************
  echo. ***** Flash Server loader V%vers% ******
  echo. ******** Paper introuvable! *******
  echo. ***********************************
  echo.
  call :pause 3
)
rem check sur internet yeah!

if %dontsearch% EQU 1 goto bypasscheck
set latestbuildonline=0
call :checkonlinebuild %version% %build%
set latestbuildonline=%errorlevel%


if %latestbuildonline% EQU -1 (
  echo. Fermeture...
  call :pause 3
  exit /b 0
)
::ici etait checkonline
set telecharge=n

if %latestbuildonline% GTR %build% (
  if %build% GTR 0 (
    echo. Nouveau build découvert pour la version %version%: %latestbuildonline%
    call :playsound
    call :pause 3
    if %latestnewsinfileandanotherscreen% == 1 (
      (
        echo ^@echo off
        echo ^chcp 65001 ^> nul
        echo ^chcp 1252 ^> nul
        echo ^echo Nouveautés
      )>%latestnewsfile%
      echo. Écriture dans le fichier %latestnewsfile% %multibuild%[34... 
    )
    if %latestnewsinfileandanotherscreen% == 0 echo. Changements dans les derniers builds: 
    call :pause 2
    call :multiNotes %version% %multibuild% %latestnewsinfileandanotherscreen%
    if %latestnewsinfileandanotherscreen% == 1 (
      echo ^pause>>%latestnewsfile%
      echo ^exit>>%latestnewsfile%
      @start /wait "Latest news" %latestnewsfile%
    )
  )
  call :pause 2
  call :downloadpapermc %version% %latestbuildonline%
  call :pause 2
  call :checklocalversion %build%
  call :pause 3
  cls
  call :title 1
  rem goto firsttime

)

if %latestbuildonline% == %build% (
  echo. Dernier build pour la version %version%: %latestbuildonline%
)
rem goto bypasspromptdownload

rem end check online
:bypasscheck
if %newversiondetected% == 1 (
  if exist %BINDIR%%fichierActuel% (
    call :pause 3
    echo. Éffacement de l'ancienne: %fichierActuel% 
    del "%BINDIR%%fichierActuel%"
  )
  call :pause 3
  if %firsttime% == 0 echo. Enregistrement de la nouvelle version... {%version% %build%}
  if %firsttime% == 1 echo. Enregistrement de la version... {%version% %build%} 
  echo %version% %build%>%versionfile%
  set firsttime=1
)
if %firsttime% == 1 (
  call :pause 5
  cls
  goto firsttime
)

rem verifier si le ficher exist avant de le lancer
if not exist %BINDIR%%fichierActuel% (
  call :pause 3
  echo. Erreur fichier %fichierActuel% introuvable!
  call :pause 3
  echo. Un instant, on va rééssayer...
  del "%BINDIR%%versionfile%"
  call :pause 3
  cls
  goto firsttime
)

call :pause 3
::start server
call :startserver %version% %build%
EXIT /B 0

:playsound
setlocal enabledelayedexpansion
set filename=playsound.vbs
set file=0
set total=0
set soundnumber=0
FOR %%i IN (%newversionfound_randomsong%) do (
  set /a total+=1
)
if %total% == 0 (
  echo. ^[Playsound^] Aucun fichier trouvé^^! ^(%newversionfound_randomsong%^)
  exit /b 1
)
set /a soundnumber=(%Random% %%(%total%))+1
set count=0
FOR %%i IN (%newversionfound_randomsong%) do (
  set /a count+=1
  if %soundnumber%==!count! set file=%%i
)
(echo Set Sound = CreateObject("WMPlayer.OCX.7"^)
echo Sound.URL = "%file%"
echo Sound.Controls.play
echo do while Sound.currentmedia.duration = 0
echo wscript.sleep 100
echo loop
echo wscript.sleep (int(Sound.currentmedia.duration^)+1^)*1000
echo Set objFSO = CreateObject("Scripting.FileSystemObject"^)
echo strScript = Wscript.ScriptFullName
echo objFSO.DeleteFile(strScript^)) >%filename%
start /min %filename%
ENDLOCAL
EXIT /B 0
::playsound end
::local check
:checklocalversion
set bu=%1
echo. Vérification local...
FOR %%i IN (paper-*.jar) do (
  if not %%i == %fichierActuel% (
    for /f "tokens=2,3 delims=-" %%a in ("%%~ni") do (
      if %%a EQU %version% (
        if %%b GTR %bu% (
          if %firsttime% == 0 echo. Nouveau build découvert localement: %%i
          if %firsttime% == 1 echo. Version découverte localement: %%i
          set version=%%a
          set build=%%b
          set newversiondetected=1
        )
        if %%b LSS %bu% (
          echo. Effacement d'ancienne version: %%i
          del "%BINDIR%%%i"
        )
      )
      if not %%a == %version% (
        echo. Effacement d'ancienne version: %%i
        del "%BINDIR%%%i"
      )
    )
  )
  set filefound=1
)
EXIT /B 0
::local check end
::check online
:checkonlinebuild
set ve=%1
set bd=%2
echo. Vérification en ligne sur papermc.io... (%ve%)

set multibuild=0
set commande='curl -s --ssl-no-revoke "https://api.papermc.io/v2/projects/paper/versions/%ve%" -H "accept: application/json"'
for /F "tokens=2 delims=[" %%a in (%commande%) do (
  for /F "tokens=1 delims=]" %%b in ("%%a") do (
    for %%c in (%%b) do (
      set /a buildsonlinenumbers+=1
      call :setmultibuilds %bd% %%c
      set bd=%%c
    )
  )
)
if %buildsonlinenumbers% LSS 1 (
  echo.
  echo. Erreur, verifiez que la version %ve% existe!
  echo.
  call :pause 5
  EXIT /B -1
)
call :pause 3
echo. Nombre total de builds pour la version %ve% est de %buildsonlinenumbers%
::trouver meilleur moyen au changement de version et plus petit build.
::if %bd% NEQ %build% (
::  echo. Reset du build n est pas pareil:  %bd%  %build%
::  set build=0
::)

EXIT /B %bd%
::check online end

:descriptions
setlocal EnableDelayedExpansion
set vers=%1
set bd=%2
set latest=%3
if %bd% == 0 EXIT /b 2
if %latest% == 1 echo ^echo %bd%:>>%latestnewsfile%
if %latest% == 0 echo. %bd%: 

set com='curl -s --ssl-no-revoke "https://api.papermc.io/v2/projects/paper/versions/%vers%/builds/%bd%" -H "accept: application/json"'
for /F "tokens=2 delims=[" %%a in (%com%) do (
  for /F "tokens=1 delims=]" %%b in ("%%a") do (
    for /F "tokens=4* delims=:" %%c in ("%%b") do (
      for /F "tokens=1 delims=}" %%e in ("%%c%%d") do (
        set messages=%%e
      )
    )
  )
)

IF [!messages!] == [] (
  echo Erreur msg is empty!
  EXIT /B 1
)

::replace \n by ^&echo.^and remove \r
set messages=%messages:<=%
set messages=%messages:>=%
set messages=%messages:&=and%
set messages=%messages:(=%
set messages=%messages:)=%
set messages=%messages:\r=%
set messages=%messages:"=%

::direct display
if %latest% == 0 ( 
  set n=^&echo.
  set messages=!messages:\n\n=\n!
  set messages=!messages:\n=%n%!
)
::display message in seperate window

if %latest% == 1 ( 
  set mess=!messages:\n\n=\n!
  set mess=!mess:\n=_!
  call :writenewstofile "!mess!"
)

if %latest% == 0 echo %messages%
endlocal
EXIT /B 0

:writenewstofile
for /F "tokens=1* delims=_" %%a in ("%~1") do (
  echo ^echo. %%a>>%latestnewsfile%
  if not "%%b" == "" call :writenewstofile "%%b"
rem add space to .txt
rem if "%%b" == "" echo. >> %latestnewsfile%
)

EXIT /B 0

:startserver
Title %title%
setlocal
set v=%1
set b=%2
echo.
echo. Démarrage du serveur paper %v% %b%...
echo.
call :pause 5
rem ajouter --forceUpgrade au bout
java -Xmx2048M -Xms2048M -Dlog4j.configurationFile=log4j2.xml -jar paper-%v%-%b%.jar nogui
endlocal
pause
EXIT /B 0

::Start donwloadpapermc
:downloadpapermc
set version=%1
set build=%2
IF %dontprompt% == 1 (
  set telecharge=o
  goto bypasspromptdownload
)

echo. Voulez-vous acquerir le fichier:

choice /C on /T 20 /D o /M ""
IF %ERRORLEVEL% EQU 2 set telecharge=n
IF %ERRORLEVEL% EQU 1 set telecharge=o
IF %ERRORLEVEL% EQU 0 set telecharge=n


:bypasspromptdownload

rem set fich=paper-%version%-%latestbuildonline%.jar
set fich=paper-%version%-%build%.jar
set url=https://api.papermc.io/v2/projects/paper/versions/%version%/builds/%build%/downloads/%fich%
IF %telecharge% == o (
  rem set url=https://api.papermc.io/v2/projects/paper/versions/%version%/builds/%latestbuildonline%/downloads/%fich%
  echo. Téléchargement en cour...
  curl -s --ssl-no-revoke -A "Mozilla/5.0 (compatible; MSIE 9.0; Windows NT 6.1; WOW64)" -H "accept: application/json" -L "%url%" -o "%BINDIR%%fich%"
  call :pause 5
  if exist %BINDIR%%fich% (
    echo. Nouveau fichier %fich% télécharger!
    call :pause 3
    echo. Un instant s'il vous plaît...
    call :pause 3
    set dontsearch=1
  )
  if not exist %BINDIR%%fich% (
    echo. Echec!
  )
)
EXIT /B 0
::End downloadpapermc
:setmultibuilds
if %2 GTR %1 (
  if %multibuild% GTR 0 set multibuild=%multibuild%-%2
  if %multibuild% EQU 0 set multibuild=%2
  
)
EXIT /B 0

:multiNotes
setlocal EnableDelayedExpansion
set ver=%1
set versions=%2
set latest=%3
IF [%1] == [] (
  echo Erreur 1 null!
  EXIT /B 1
)
IF [%2] == [] (
  echo Erreur 2 null!
  EXIT /B 2
)
set versions=!versions:-= !
FOR %%a in (%versions%) do (
  call :descriptions %ver% %%a %latest%
  if %latest% == 0 call :pause 2
)
endlocal
EXIT /B 0
:pause
ping 127.0.0.1 -n %1 > nul
EXIT /B 0
:title
cls
echo.
echo. ***********************************
echo. ***** Flash Server loader V%vers% ******
echo. ** Version Actuel: %version% b: %build% **
echo. ***********************************
echo.
exit /b 0