BasicShowItem/build.gradle.kts at main · FireML-Dev/BasicShowItem · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
import net.minecrell.pluginyml.bukkit.BukkitPluginDescription

plugins {
    `java-library`
    id("de.eldoria.plugin-yml.bukkit") version "0.7.1"
    id("com.gradleup.shadow") version "9.0.0"
}

repositories {
    mavenCentral()
    gradlePluginPortal()
    maven("https://repo.papermc.io/repository/maven-public/")
}

dependencies {
    compileOnly("io.papermc.paper:paper-api:1.20.1-R0.1-SNAPSHOT")
    implementation("org.bstats:bstats-bukkit:3.0.2")
}

group = "uk.firedev"
version = "1.0.3"
description = "Show your held item in chat"
java.sourceCompatibility = JavaVersion.VERSION_21

bukkit {
    name = rootProject.name
    version = project.version.toString()
    main = "uk.firedev.basicshowitem.BasicShowItem"
    apiVersion = "1.20"
    author = "FireML"
    description = project.description.toString()

    permissions {
        register("basicshowitem.use") {
            description = "Allows the player to show their held item in chat"
            default = BukkitPluginDescription.Permission.Default.TRUE
        }
    }

    commands {
        register("basicshowitem") {
            description = "Show your held item in chat"
            aliases = listOf("showitem")
        }
    }
}

tasks {
    build {
        dependsOn(shadowJar)
    }
    shadowJar {
        archiveBaseName.set(project.name)
        archiveVersion.set(project.version.toString())
        archiveClassifier.set("")
        minimize()

        relocate("org.bstats", "uk.firedev.basicshowitem.libs.bstats")
    }
    jar {
        enabled = false
    }
    withType<JavaCompile> {
        options.encoding = "UTF-8"
    }
}