Clientizen/build.gradle at main · DenizenScript/Clientizen · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
plugins {
    id 'net.fabricmc.fabric-loom' version "${loom_version}"
    id 'maven-publish'
}

version = project.version + '-' + project.build_number
group = project.maven_group

base {
    archivesName = project.archives_base_name
}

repositories {
    mavenCentral()
    // Uncomment to build with local Denizen-Core changes
    // mavenLocal()
    maven {
        name = "Denizen"
        url = "https://maven.citizensnpcs.co/repo"
    }
    maven {
        name = "DevAuth"
        url = "https://pkgs.dev.azure.com/djtheredstoner/DevAuth/_packaging/public/maven/v1"
    }
    maven {
        name = "CottonMC"
        url = "https://staging.alexiil.uk/maven"
    }
}

dependencies {
    // To change the versions see the gradle.properties file
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    implementation "net.fabricmc:fabric-loader:${project.loader_version}"

    implementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"
    implementation include("io.github.cottonmc:LibGui:${project.libgui_version}")

    implementation include("com.denizenscript:denizencore:${project.denizencore_version}")
    implementation include("org.yaml:snakeyaml:${project.snakeyaml_version}")

    runtimeOnly "me.djtheredstoner:DevAuth-fabric:${project.devauth_version}"
}

loom {
    runs {
        client {
            property("devauth.enabled", "true")
            property("devauth.account", "alt") // DevAuth's name for the Microsoft account in the default config
        }
    }
    accessWidenerPath = file("src/main/resources/clientizen.classtweaker")
}

processResources {
    inputs.property "version", project.version

    filesMatching("fabric.mod.json") {
        expand "version": project.version
    }
}

tasks.withType(JavaCompile).configureEach {
    it.options.release = 25
}

java {
    sourceCompatibility = JavaVersion.VERSION_21
    targetCompatibility = JavaVersion.VERSION_21
}

jar {
    from("LICENSE") {
        rename { "${it}_${project.base.archivesName.get()}"}
    }
}

publishing {
    publications {
        create("mavenJava", MavenPublication) {
            artifactId = project.archives_base_name
            from components.java
        }
    }
}