struct-layout/build.gradle at main · Deanly/struct-layout · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
plugins {
    id 'java'
    id 'signing'
    id 'maven-publish'
    id 'org.jreleaser' version '1.16.0'
}

group = 'net.deanly'
version = '0.3.5'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(17)
    }
    withJavadocJar()
    withSourcesJar()
}

repositories {
    mavenCentral()
}

dependencies {
    compileOnly 'org.projectlombok:lombok:1.18.36'
    annotationProcessor 'org.projectlombok:lombok:1.18.36'
    testCompileOnly 'org.projectlombok:lombok:1.18.36'
    testAnnotationProcessor 'org.projectlombok:lombok:1.18.36'

    testImplementation 'org.junit.jupiter:junit-jupiter:5.10.0'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.10.0'
    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.11.4'
    testImplementation 'org.mockito:mockito-core:5.14.2'
}

tasks.withType(Test) {
    useJUnitPlatform()
}
tasks.withType(Javadoc) { // Disabled Javadoc due to Lombok Builder issues
    enabled = false
}
tasks.named("build") {
    doFirst {
        file("$buildDir/jreleaser").mkdirs()
    }
}

publishing {
    publications {
        maven(MavenPublication) {
            from components.java

            pom {
                name.set('StructLayout')
                description.set('A Java library for structured binary data handling')
                url.set('https://github.com/deanly/struct-layout')
                inceptionYear.set('2025')
                licenses {
                    license {
                        name.set('MIT License')
                        url.set('https://opensource.org/licenses/MIT')
                    }
                }
                scm {
                    connection.set('scm:git:https://github.com/deanly/struct-layout.git')
                    developerConnection.set('scm:git:ssh://github.com/deanly/struct-layout.git')
                    url.set('https://github.com/deanly/struct-layout')
                }
                developers {
                    developer {
                        id.set('deanly')
                        name.set('Dean Lee')
                        email.set('deanly.dev@gmail.com')
                    }
                }
            }
        }
    }
    repositories {
        maven {
            url = layout.buildDirectory.dir('staging-deploy')
        }
    }
}

jreleaser {
    signing {
        active = 'ALWAYS'
        armored = true
    }
    deploy {
        maven {
            mavenCentral {
                sonatype {
                    active = 'ALWAYS'
                    url = 'https://central.sonatype.com/api/v1/publisher'
                    stagingRepository('build/staging-deploy')
                }
            }
        }
    }
    project {
        name = 'struct-layout'
        description = 'A Java library for structured binary data handling'
        website = 'https://github.com/deanly/struct-layout'
        license = 'MIT'
    }

    gitRootSearch = true
    release {
        github {
            enabled = true
            setRepoOwner('Deanly')
            name = 'struct-layout'
            tagName = 'v{{projectVersion}}'
            releaseName = 'Release {{tagName}}'
        }
    }
}