MoreHitboxes/build.gradle at 1.18.2 · DarkPred/MoreHitboxes · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
subprojects {
    apply plugin: 'java'

    version = mod_version
    group = maven_group

    java.toolchain.languageVersion = JavaLanguageVersion.of(java_version)
    java.withSourcesJar()
    //java.withJavadocJar()

    base {
        //Jar name
        archivesName = "$archives_name-${project.name}-$minecraft_version"
    }

    jar {
        from(rootProject.file("LICENSE")) {
            rename { "${it}_$mod_name" }
        }
        manifest {
            attributes([
                    'Specification-Title'     : mod_name,
                    'Specification-Vendor'    : mod_author,
                    'Specification-Version'   : project.jar.archiveVersion,
                    'Implementation-Title'    : project.name,
                    'Implementation-Version'  : project.jar.archiveVersion,
                    'Implementation-Vendor'   : mod_author,
                    'Implementation-Timestamp': new Date().format("yyyy-MM-dd'T'HH:mm:ssZ"),
                    'Timestamp'               : System.currentTimeMillis(),
                    'Built-On-Java'           : "${System.getProperty('java.vm.version')} (${System.getProperty('java.vm.vendor')})",
                    'Build-On-Minecraft'      : minecraft_version
            ])
        }
    }

    sourcesJar {
        from(rootProject.file("LICENSE")) {
            rename { "${it}_$mod_name" }
        }
    }

    repositories {

        mavenCentral()

        maven {
            name = 'Sponge / Mixin'
            url = 'https://repo.spongepowered.org/repository/maven-public/'
        }

        maven {
            name = 'BlameJared Maven (CrT / Bookshelf)'
            url = 'https://maven.blamejared.com'
        }
        maven {
            name = 'GeckoLib'
            url = 'https://dl.cloudsmith.io/public/geckolib3/geckolib/maven/'
        }
        maven { url = 'https://maven.parchmentmc.org' }
    }

    tasks.withType(JavaCompile).configureEach {
        options.encoding = 'UTF-8'
        options.release = java_version.toInteger()
    }
    tasks.withType(Javadoc).configureEach {
        options.tags("apiNote:a:API Note:")
        options.tags("implSpec:a:Implementation Requirements:")
        options.tags("implNote:a:Implementation Note:")
    }

    // Disables Gradle's custom module metadata from being published to maven. The
    // metadata includes mapped dependencies which are not reasonably consumable by
    // other mod developers.
    tasks.withType(GenerateModuleMetadata) {

        enabled = false
    }
}