adds optional proxy python binding generation

Author: Luke Pickering

CMakeLists.txt

@@ -9,6 +9,8 @@ list(GET VERSION_LIST 2 duneanaobj_VERSION_PATCH)
 
 LIST(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_LIST_DIR}/cmake/Modules)
 
+option(duneanaobj_PYTHON_ENABLED "Whether to build python bindings to proxy classes." OFF)
+
 include(CPM)
 
 SET(SRProxy_MIN_VERSION 0.46.0)

duneanaobj/StandardRecord/CMakeLists.txt

@@ -1,5 +1,5 @@
 execute_process(COMMAND git rev-parse --short=8 HEAD
-  WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/../.. 
+  WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/../..
   OUTPUT_VARIABLE duneanaobj_GITSHORTHASH8
   RESULT_VARIABLE GIT_CMD_SUCCESS
   OUTPUT_STRIP_TRAILING_WHITESPACE)
@@ -74,19 +74,19 @@ SET(SR_HEADER_FILES
 )
 
 add_library(duneanaobj_StandardRecord SHARED ${SR_IMPL_FILES})
-target_link_libraries(duneanaobj_StandardRecord PUBLIC ROOT::MathCore)
-target_include_directories(duneanaobj_StandardRecord PUBLIC 
-  $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/../..> 
+target_link_libraries(duneanaobj_StandardRecord PUBLIC ROOT::Physics ROOT::MathCore)
+target_include_directories(duneanaobj_StandardRecord PUBLIC
+  $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/../..>
   $<INSTALL_INTERFACE:include>)
-target_include_directories(duneanaobj_StandardRecord PRIVATE 
+target_include_directories(duneanaobj_StandardRecord PRIVATE
   $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}> #root puts this in the dictionary
   )
 set_target_properties(duneanaobj_StandardRecord PROPERTIES EXPORT_NAME StandardRecord)
 install(TARGETS duneanaobj_StandardRecord EXPORT duneanaobj_targets DESTINATION lib)
 install(FILES ${SR_HEADER_FILES} DESTINATION include/duneanaobj/StandardRecord)
-install(FILES 
-    ${CMAKE_CURRENT_BINARY_DIR}/libStandardRecordDict_rdict.pcm 
-    ${CMAKE_CURRENT_BINARY_DIR}/libStandardRecordDict.rootmap 
+install(FILES
+    ${CMAKE_CURRENT_BINARY_DIR}/libStandardRecordDict_rdict.pcm
+    ${CMAKE_CURRENT_BINARY_DIR}/libStandardRecordDict.rootmap
   DESTINATION lib)
 
 add_library(duneanaobj::StandardRecord ALIAS duneanaobj_StandardRecord)
@@ -99,4 +99,4 @@ foreach(HDR ${SR_HEADER_FILES})
 endforeach()
 
 add_subdirectory(Proxy)
-add_subdirectory(Flat)
+add_subdirectory(Flat)

duneanaobj/StandardRecord/Proxy/CMakeLists.txt

@@ -6,18 +6,51 @@ GenSRProxy(
   EPILOG_FWD ${CMAKE_CURRENT_SOURCE_DIR}/EpilogFwd.h
   INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/../../.. ${ROOT_INCLUDE_DIRS}
   DEPENDENCIES ${SR_HEADER_FILE_FQPS}
+  EMIT_PYTHON_BINDINGS
   VVERBOSE)
 
 add_library(duneanaobj_StandardRecordProxy SHARED SRProxy.cxx)
-target_link_libraries(duneanaobj_StandardRecordProxy PUBLIC SRProxy::BasicTypes)
-target_include_directories(duneanaobj_StandardRecordProxy PUBLIC 
+target_link_libraries(duneanaobj_StandardRecordProxy PUBLIC SRProxy::BasicTypes duneanaobj_StandardRecord)
+target_include_directories(duneanaobj_StandardRecordProxy PUBLIC
   $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/../../..>
   $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}/../../..>
   $<INSTALL_INTERFACE:include>)
 
 install(TARGETS duneanaobj_StandardRecordProxy EXPORT duneanaobj_targets DESTINATION lib)
-install(FILES ${CMAKE_CURRENT_BINARY_DIR}/SRProxy.h 
-              ${CMAKE_CURRENT_BINARY_DIR}/FwdDeclare.h 
+install(FILES ${CMAKE_CURRENT_BINARY_DIR}/SRProxy.h
+              ${CMAKE_CURRENT_BINARY_DIR}/FwdDeclare.h
         DESTINATION include/duneanaobj/StandardRecord/Proxy)
 
 add_library(duneanaobj::StandardRecordProxy ALIAS duneanaobj_StandardRecordProxy)
+
+if(duneanaobj_PYTHON_ENABLED)
+  find_package(Python3 REQUIRED COMPONENTS Development Interpreter)
+
+  # PYTHON PATHS
+  set(duneanaobj_PYTHONPATH "python/${Python3_VERSION_MAJOR}.${Python3_VERSION_MINOR}")
+
+  include(FetchContent)
+
+  FetchContent_Declare(
+    pybind11
+    GIT_REPOSITORY https://github.com/pybind/pybind11.git
+    GIT_TAG        f5fbe86 # release-3.0.1
+  )
+
+  FetchContent_MakeAvailable(pybind11)
+
+  pybind11_add_module(pySRProxy SHARED SRProxy.pybind.cxx)
+
+  target_include_directories(pySRProxy
+    PRIVATE
+      $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
+      $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/src/include>
+      )
+
+  target_link_libraries(pySRProxy
+    PRIVATE
+      duneanaobj::StandardRecordProxy)
+
+  install(TARGETS pySRProxy
+      LIBRARY DESTINATION ${duneanaobj_PYTHONPATH})
+endif()