Mod_Forge_Legacy/build.gradle.kts at main · CommunityRadarGG/Mod_Forge_Legacy · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
/*
 * Copyright 2024 - present CommunityRadarGG <https://community-radar.de/>
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */
plugins {
    id("java")
    alias(libs.plugins.spotless)
    alias(libs.plugins.ggEssentialLoom) apply false
}

val groupTextProvider = providers.gradleProperty("maven_group")
val versionTextProvider = providers.gradleProperty("mod_version")
val modIdProvider = providers.gradleProperty("mod_id")

allprojects {
    group = groupTextProvider.get()
    version = versionTextProvider.get()

    repositories {
        mavenCentral()
    }

    plugins.withId("com.diffplug.spotless") {
        spotless {
            java {
                licenseHeaderFile(rootProject.file("HEADER"))
                endWithNewline()
                trimTrailingWhitespace()
                removeUnusedImports()
                removeWildcardImports()
            }

            kotlinGradle {
                licenseHeaderFile(rootProject.file("HEADER"), "(plugins|import|buildscript|pluginManagement|base)")
                endWithNewline()
                trimTrailingWhitespace()
            }

            kotlin {
                licenseHeaderFile(rootProject.file("HEADER"))
                endWithNewline()
                trimTrailingWhitespace()
            }
        }
    }
}

subprojects {
    apply(plugin = "java")
    apply(plugin = rootProject.libs.plugins.spotless.get().pluginId)

    val computedVersion = if (path.startsWith(":versions:")) {
        "${versionTextProvider.get()}+$name"
    } else {
        versionTextProvider.get()
    }

    version = computedVersion

    extra["versionText"] = computedVersion
    extra["modIdText"] = modIdProvider.get()

    base {
        archivesName.set(modIdProvider.get())
    }

    project(":versions").childProjects.values.forEach { versionProject ->
        versionProject.apply(plugin = rootProject.libs.plugins.ggEssentialLoom.get().pluginId)
    }

    java {
        toolchain {
            languageVersion.set(JavaLanguageVersion.of(8))
        }
    }

    tasks {
        withType<JavaCompile> {
            options.encoding = Charsets.UTF_8.name()
        }

        withType<Jar> {
            from(rootProject.layout.projectDirectory) {
                include("LICENSE", "NOTICE")
            }

            manifest {
                attributes(
                    "Specification-Title" to rootProject.name,
                    "Specification-Version" to versionTextProvider.get(),
                    "Implementation-Title" to rootProject.name,
                    "Implementation-Version" to versionTextProvider.get()
                )
            }

            plugins.withId(rootProject.libs.plugins.ggEssentialLoom.get().pluginId) {
                val remapJarTask = named("remapJar")

                register<Copy>("copyRemappedJars") {
                    dependsOn(remapJarTask)
                    from(remapJarTask.map { it.outputs.files })
                    into(rootProject.layout.buildDirectory.dir("libs"))
                }

                named("build") {
                    finalizedBy("copyRemappedJars")
                }
            }
        }
    }
}

tasks {
    named<Jar>("jar").configure {
        enabled = false
    }
}