rssbot/flake.nix at master · Brawl345/rssbot · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
{
  description = "RSS bot for Telegram";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs?ref=nixpkgs-unstable";
  };

  outputs =
    { self, nixpkgs, ... }:

    let
      forAllSystems =
        function:
        nixpkgs.lib.genAttrs [
          "x86_64-linux"
          "aarch64-linux"
          "x86_64-darwin"
          "aarch64-darwin"
        ] (system: function nixpkgs.legacyPackages.${system});

      version = if (self ? shortRev) then self.shortRev else "dev";
    in
    {

      nixosModules = {
        default = ./module.nix;
      };

      overlays.default = final: prev: {
        rssbot = self.packages.${prev.system}.default;
      };

      devShells = forAllSystems (pkgs: {
        default = pkgs.mkShell {
          packages = [
            pkgs.go
            pkgs.golangci-lint
          ];
        };
      });

      packages = forAllSystems (pkgs: {
        rssbot = pkgs.buildGoModule {
          pname = "rssbot";
          inherit version;
          src = pkgs.lib.cleanSource self;

          # Update the hash if go dependencies change!
          # vendorHash = pkgs.lib.fakeHash;
          vendorHash = "sha256-mo30V7ISVFY8Rl3yXChP6pbehV9hTPH3UlBLDb1dzNE=";

          ldflags = [
            "-s"
            "-w"
          ];

          meta = {
            description = "RSS bot for Telegram";
            homepage = "https://github.com/Brawl345/rssbot";
            license = pkgs.lib.licenses.unlicense;
            platforms = pkgs.lib.platforms.darwin ++ pkgs.lib.platforms.linux;
          };
        };

        default = self.packages.${pkgs.system}.rssbot;
      });
    };
}