CMakeLists.txt

# hibp2sqlite
# Copyleft 2025
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <https://www.gnu.org/licenses/>.

cmake_minimum_required(VERSION 3.16)

project(hibp2sqlite LANGUAGES CXX)

if(WIN32)
set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/dist")
elseif(UNIX)
set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/linux/AppDir/usr")
set(CMAKE_INSTALL_RPATH "$ORIGIN" "$ORIGIN/../lib")
endif()

set(CMAKE_AUTOUIC ON)
set(CMAKE_AUTOMOC ON)
set(CMAKE_AUTORCC ON)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

find_package(QT NAMES Qt6 REQUIRED COMPONENTS Core Sql)
find_package(Qt${QT_VERSION_MAJOR} REQUIRED COMPONENTS Core Sql)

set(PROJECT_SOURCES
    main.cpp
    hibp2sqlite.rc
)

set(RESOURCE
    "hibp2sqlite.qrc"
)

qt_add_resources(PROJECT_RESOURCES ${RESOURCE})

qt_add_executable(hibp2sqlite
    ${PROJECT_SOURCES}
    ${PROJECT_RESOURCES}
)

target_link_libraries(hibp2sqlite PRIVATE
    Qt${QT_VERSION_MAJOR}::Core
    Qt${QT_VERSION_MAJOR}::Sql)

include(GNUInstallDirs)
install(TARGETS hibp2sqlite
    LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
)

# Run Qt Deploy Tool
set(MY_APP hibp2sqlite)
set(deploy_script "${CMAKE_CURRENT_BINARY_DIR}/deploy_${MY_APP}_${CMAKE_BUILD_TYPE}.cmake")

if(WIN32)
    set(executable_path "\${QT_DEPLOY_BIN_DIR}/$<TARGET_FILE_NAME:${MY_APP}>")
    file(GENERATE OUTPUT ${deploy_script} CONTENT "
include(\"${QT_DEPLOY_SUPPORT}\")
qt_deploy_runtime_dependencies(
    EXECUTABLE \"${executable_path}\"
    PLUGINS_DIR bin
    NO_TRANSLATIONS
    NO_COMPILER_RUNTIME)"
    )

    set(zip_script "${CMAKE_CURRENT_BINARY_DIR}/zip_${MY_APP}_${CMAKE_BUILD_TYPE}.cmake")
    file(GENERATE OUTPUT ${zip_script} CONTENT "
message(\"Creating ${CMAKE_CURRENT_SOURCE_DIR}/dist/${MY_APP}.zip ...\")
file(MAKE_DIRECTORY
    \"${CMAKE_CURRENT_SOURCE_DIR}/dist\")
file(ARCHIVE_CREATE
    OUTPUT \"${CMAKE_CURRENT_SOURCE_DIR}/dist/${MY_APP}.zip\"
    WORKING_DIRECTORY \"${CMAKE_CURRENT_SOURCE_DIR}/dist/bin\"
    PATHS 
        \".\"
    FORMAT \"zip\")
message(\"Created ${CMAKE_CURRENT_SOURCE_DIR}/dist/${MY_APP}.zip\")"
    )
elseif(UNIX)
    # Generate the deployment script for the target MY_APP.
    qt_generate_deploy_app_script(
        TARGET ${MY_APP}
        OUTPUT_SCRIPT deploy_script
        NO_UNSUPPORTED_PLATFORM_ERROR
        NO_TRANSLATIONS
        NO_COMPILER_RUNTIME    
    )

    set(tar_script "${CMAKE_CURRENT_BINARY_DIR}/tar_${MY_APP}_${CMAKE_BUILD_TYPE}.cmake")
    file(GENERATE OUTPUT ${tar_script} CONTENT "
message(\"Creating ${CMAKE_CURRENT_SOURCE_DIR}/dist/${MY_APP}.tar.gz ...\")
file(MAKE_DIRECTORY
    \"${CMAKE_CURRENT_SOURCE_DIR}/dist\")
file(ARCHIVE_CREATE
    OUTPUT \"${CMAKE_CURRENT_SOURCE_DIR}/dist/${MY_APP}.tar.gz\"
    WORKING_DIRECTORY \"${CMAKE_CURRENT_SOURCE_DIR}/linux\"
    PATHS 
        \"AppDir\"
    FORMAT \"gnutar\"
    COMPRESSION \"GZip\")
message(\"Created ${CMAKE_CURRENT_SOURCE_DIR}/dist/${MY_APP}.tar.gz\")"
    )
endif()

if(WIN32)
install(TARGETS ${MY_APP} DESTINATION bin)
install(SCRIPT ${deploy_script})
install(SCRIPT ${zip_script})
elseif(UNIX)
install(SCRIPT ${deploy_script})
install(SCRIPT ${tar_script})
endif()