hytaletrack-server-plugin/build.gradle.kts at main · BlockhostOfficial/hytaletrack-server-plugin · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
plugins {
    base
    id("java")
    id("com.diffplug.spotless") version "8.4.0"
    id("net.ltgt.errorprone") version "5.1.0"
    id("com.github.spotbugs") version "6.4.8"
    id("org.openrewrite.rewrite") version "7.30.0"
}

val hytaleServerVersion = "2026.03.26-92489d5e7"
val releaseVersion = providers.gradleProperty("releaseVersion").orElse("1.0.0-SNAPSHOT")

tasks.named<UpdateDaemonJvm>("updateDaemonJvm") {
    languageVersion = JavaLanguageVersion.of(25)
}

spotless {
    java {
        trimTrailingWhitespace()
        leadingTabsToSpaces(2)
        endWithNewline()
    }
}

rewrite {
    activeRecipe("org.openrewrite.staticanalysis.CommonStaticAnalysis")
    activeRecipe("org.openrewrite.staticanalysis.CodeCleanup")
    activeRecipe("org.openrewrite.staticanalysis.JavaApiBestPractices")
    activeRecipe("org.openrewrite.java.migrate.UpgradeToJava25")
    isExportDatatables = true
}

spotbugs {
    ignoreFailures = true
}

group = "com.hytaletrack"
version = releaseVersion.get()
description = "Submit server data to HytaleTrack for display on player and server profiles"

repositories {
    maven("https://maven.hytale.com/release") {
        name = "hytale-release"
        mavenContent {
            releasesOnly()
        }
        content {
            includeGroup("com.hypixel.hytale")
        }
    }
    maven("https://maven.hytale.com/pre-release") {
        name = "hytale-pre-release"
        mavenContent {
            releasesOnly()
        }
        content {
            includeGroup("com.hypixel.hytale")
        }
    }
    mavenCentral()
}

dependencies {
    errorprone("com.google.errorprone:error_prone_core:2.49.0")
    spotbugs("com.github.spotbugs:spotbugs:4.9.8")

    rewrite("org.openrewrite.recipe:rewrite-static-analysis:2.32.0")
    rewrite("org.openrewrite.recipe:rewrite-migrate-java:3.32.0")
    rewrite("org.openrewrite.recipe:rewrite-rewrite:0.23.0")

    compileOnly("com.hypixel.hytale:Server:$hytaleServerVersion")
    implementation("com.google.code.gson:gson:2.13.2")
    testImplementation(platform("org.junit:junit-bom:6.0.3"))
    testImplementation("org.junit.jupiter:junit-jupiter")
    testRuntimeOnly("org.junit.platform:junit-platform-launcher")
}

tasks {
    processResources {
        inputs.property("version", project.version)
        inputs.property("description", project.description ?: "")

        filesMatching(
            listOf(
                "manifest.json"
            )
        ) {
            expand(inputs.properties)
        }
    }
    test {
        useJUnitPlatform()
    }
}