KONECT_BACK_END/build.gradle at develop · BCSDLab/KONECT_BACK_END · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
plugins {
	id 'java'
	id 'org.springframework.boot' version '3.5.8'
	id 'io.spring.dependency-management' version '1.1.7'
	id 'checkstyle'
	id 'jacoco'
}

group = 'gg.agit'
version = '0.0.1-SNAPSHOT'

java {
	toolchain {
		languageVersion = JavaLanguageVersion.of(21)
	}
}

configurations {
	compileOnly {
		extendsFrom annotationProcessor
	}
}

repositories {
	mavenCentral()
}

dependencies {
    // spring boot starter
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-security'
    implementation 'org.springframework.boot:spring-boot-starter-actuator'
    implementation 'org.springframework.boot:spring-boot-starter-aop'
    implementation 'org.springframework.retry:spring-retry'
    implementation 'org.springframework.boot:spring-boot-starter-data-redis'

    // db
    implementation 'com.mysql:mysql-connector-j'
    runtimeOnly 'com.mysql:mysql-connector-j'
    implementation 'org.flywaydb:flyway-mysql'

    // lombok
    compileOnly 'org.projectlombok:lombok'
    annotationProcessor 'org.projectlombok:lombok'

    // swagger
    implementation 'org.springdoc:springdoc-openapi-starter-webmvc-ui:2.8.14'

    // notification
    implementation 'com.github.maricn:logback-slack-appender:1.4.0'
    implementation 'net.logstash.logback:logstash-logback-encoder:8.0'
    implementation 'com.slack.api:slack-api-client:1.44.2'

    // querydsl
    implementation 'com.querydsl:querydsl-jpa:5.0.0:jakarta'
    annotationProcessor "com.querydsl:querydsl-apt:5.0.0:jakarta"
    annotationProcessor "jakarta.annotation:jakarta.annotation-api"
    annotationProcessor "jakarta.persistence:jakarta.persistence-api"

    // OAuth
    implementation 'org.springframework.boot:spring-boot-starter-oauth2-client'

    // AWS SDK v2
    implementation platform('software.amazon.awssdk:bom:2.41.14')
    implementation 'software.amazon.awssdk:s3'


    // notification
    implementation 'com.google.firebase:firebase-admin:9.2.0'

    // Google Sheets API
    implementation 'com.google.apis:google-api-services-sheets:v4-rev20251110-2.0.0'
    implementation 'com.google.auth:google-auth-library-oauth2-http:1.23.0'

    // Google Drive API
    implementation 'com.google.apis:google-api-services-drive:v3-rev20250723-2.0.0'

    // Gemini AI - using REST API directly (no SDK dependency)

    // test
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testImplementation 'org.springframework.security:spring-security-test'
    testImplementation 'org.testcontainers:testcontainers'
    testImplementation 'org.testcontainers:junit-jupiter'
    testImplementation 'org.testcontainers:mysql'
    testImplementation 'com.github.codemonstur:embedded-redis:1.4.3'
    testRuntimeOnly 'com.h2database:h2'
    testCompileOnly 'org.projectlombok:lombok'
    testAnnotationProcessor 'org.projectlombok:lombok'
}

clean {
    delete file('src/main/generated')
}

bootJar {
	archiveFileName = 'KONECT_API.jar'
}

jar {
    enabled = false
}

tasks.named('test') {
	useJUnitPlatform()

	maxParallelForks = Math.min(Runtime.runtime.availableProcessors(), 4)
	reports {
		// CI는 JUnit XML만으로 충분하므로 HTML 리포트 생성 비용은 줄인다.
		html.required = !System.getenv().containsKey('CI')
	}
}

// JaCoCo 커버리지 리포트 설정
jacocoTestReport {
	dependsOn test

	reports {
		xml.required = true
		html.required = true
	}

	// 커버리지에서 제외할 클래스 설정
	afterEvaluate {
		classDirectories.setFrom(
			fileTree(layout.buildDirectory.dir("classes/java/main")) {
				exclude([
					// DTO (dto 패키지 내부만 제외)
					"**/dto/*.class",
					// Entity
					"**/domain/**/model/*.class",
					"**/model/*.class",
					// Configuration
					"**/config/*.class",
					"**/*Config.class",
					// Exception
					"**/exception/*.class",
					"**/*Exception.class",
					// 외부 API 클라이언트 (단위 테스트 어려운 클래스)
					"**/infrastructure/claude/**",
					"**/infrastructure/mcp/**",
					// 기타
					"**/Application.class",  // Spring Boot 메인 클래스
				])
			}
		)
	}
}

tasks.named('check') {
	dependsOn jacocoTestReport
}

checkstyle {
	toolVersion = '10.12.5'
	configFile = file("${rootDir}/config/checkstyle/checkstyle.xml")
	configProperties = ['suppressionFile': "${rootDir}/config/checkstyle/suppressions.xml"]
	maxWarnings = 0
	ignoreFailures = false
}

checkstyleMain {
	source = 'src/main/java'
}

tasks.named('build') {
	dependsOn 'checkstyleMain'
}