EventHorizon/build.gradle.kts at trunk · Automattic/EventHorizon · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
import com.diffplug.gradle.spotless.BaseKotlinExtension
import com.diffplug.gradle.spotless.FormatExtension
import com.diffplug.gradle.spotless.SpotlessExtension
import com.diffplug.gradle.spotless.SpotlessExtensionPredeclare
import com.diffplug.spotless.LineEnding
import io.gitlab.arturbosch.detekt.Detekt
import io.gitlab.arturbosch.detekt.extensions.DetektExtension
import org.gradle.api.tasks.testing.logging.TestExceptionFormat
import org.jetbrains.kotlin.gradle.dsl.JvmTarget
import org.jetbrains.kotlin.gradle.dsl.KotlinProjectExtension
import org.jetbrains.kotlin.gradle.plugin.KotlinBasePlugin
import org.jetbrains.kotlin.gradle.tasks.KotlinJvmCompile

plugins {
  alias(libs.plugins.buildconfig) apply false
  alias(libs.plugins.kotlin.jvm) apply false
  alias(libs.plugins.kotlin.serialization) apply false
  alias(libs.plugins.detekt) apply false
  alias(libs.plugins.spotless)
}

val spotlessPluginId = libs.plugins.spotless.get().pluginId
val ktlintVersion = libs.versions.ktlint.get()

allprojects {
  apply(plugin = spotlessPluginId)
  val spotlessFormatters: SpotlessExtension.() -> Unit = {
    lineEndings = LineEnding.UNIX

    val formatExtension: FormatExtension.() -> Unit = {
      trimTrailingWhitespace()
      endWithNewline()
    }

    val baseKotlinExtension: BaseKotlinExtension.() -> Unit = {
      val configOverride = mapOf(
        "ktlint_standard_function-expression-body" to "disabled",
        "ktlint_standard_multiline-expression-wrapping" to "disabled",
        "ktlint_standard_class-signature" to "disabled",
        "ktlint_standard_property-naming" to "disabled",
      )
      ktlint(ktlintVersion).editorConfigOverride(configOverride)
      formatExtension()
    }

    kotlin {
      target("src/**/*.kt")
      baseKotlinExtension()
    }

    kotlinGradle {
      target("*.kts")
      baseKotlinExtension()
    }

    format("misc") {
      target("*.gitignore", "*.toml", "*.md", "*.properties")
      formatExtension()
    }
  }
  configure<SpotlessExtension> {
    spotlessFormatters()
    if (rootProject == project) {
      predeclareDeps()
    }
  }
  if (rootProject == project) {
    configure<SpotlessExtensionPredeclare> { spotlessFormatters() }
  }
}

val jdkVersion = JavaLanguageVersion.of(libs.versions.jdk.get())
val jvmTargetVersion = JvmTarget.fromTarget(libs.versions.jvmTarget.get())
val detektPluginId = libs.plugins.detekt.get().pluginId
val detektVersion = libs.versions.detekt.get()

subprojects {
  group = property("GROUP") as String
  version = property("VERSION_NAME") as String

  plugins.withType<JavaBasePlugin> {
    configure<JavaPluginExtension> {
      toolchain {
        languageVersion.set(jdkVersion)
      }
    }
  }

  tasks.withType<JavaCompile>().configureEach {
    sourceCompatibility = jvmTargetVersion.target
    targetCompatibility = jvmTargetVersion.target
  }

  plugins.withType<KotlinBasePlugin>().configureEach {
    configure<KotlinProjectExtension> {
      explicitApi()
    }
  }

  tasks.withType<KotlinJvmCompile>().configureEach {
    compilerOptions {
      jvmTarget.set(jvmTargetVersion)
      progressiveMode.set(true)
      allWarningsAsErrors.set(true)
      freeCompilerArgs.addAll("-Xannotation-default-target=param-property")
    }
  }

  apply(plugin = detektPluginId)
  configure<DetektExtension> {
    toolVersion = detektVersion
    allRules = true
    buildUponDefaultConfig = true
  }

  val buildDir = layout.buildDirectory.asFile.get().canonicalPath
  tasks.withType<Detekt>().configureEach {
    jvmTarget = jvmTargetVersion.target
    config.from(rootProject.file("detekt.yml"))
    exclude { it.file.canonicalPath.startsWith(buildDir) }
    reports {
      html.required.set(true)
      xml.required.set(true)
      txt.required.set(true)
    }
  }

  tasks.withType<Test>().configureEach {
    useJUnitPlatform()
    testLogging {
      events("started", "passed", "failed", "skipped")
      exceptionFormat = TestExceptionFormat.FULL
    }
  }
}