acdasm/cli/build.gradle at ca0dffb8312bcd2fc67ae31e96fac60d03ea1879 · AppleCommander/acdasm · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
plugins {
    id 'org.springframework.boot' version "4.0.3"
    id 'java'
    id 'application'
    id 'org.graalvm.buildtools.native' version '0.11.4'
}

java {
    sourceCompatibility = 21
    targetCompatibility = 21
}

repositories {
    mavenCentral()
}

dependencies {
    implementation project(':api')
    implementation 'info.picocli:picocli:4.7.7'
    annotationProcessor 'info.picocli:picocli-codegen:4.7.7'
}

compileJava {
    options.compilerArgs += ["-Aproject=${project.group}/${project.name}"]
}

jar {
    archiveVersion = acdasmVersion
}

application {
    mainClass = 'org.applecommander.disassembler.cli.Main'
}

// Disable all Spring AOT processing
processAot.configure {
    enabled = false;
}
processTestAot.configure {
    enabled = false;
}

bootJar {
    archiveBaseName = 'acdasm'
    archiveVersion = acdasmVersion
    manifest {
        attributes 'Implementation-Title': "AppleCommander 'acdasm'",
                   'Implementation-Version': acdasmVersion
    }
}

graalvmNative {
    String osName = System.getProperty('os.name').toLowerCase().split()[0]
    String osArch = System.getProperty('os.arch').toLowerCase().split()[0]
    binaries {
        named("main") {
            imageName.set("acdasm-${osName}-${osArch}-${acdasmVersion}")
        }
    }
}